Set $Data::Dumper::Purity to 1:

#!/usr/bin/perl

use Data::Dumper;
$Data::Dumper::Purity = 1;

$old = { name => "bob" };
$young = { name => "bob jr" };

$old->{child} = $young;
$young->{parent} = $old;

$string = Data::Dumper->Dump([$old],[qw(old)]);

undef $old;
undef $young;

eval "$string";

$check = Data::Dumper->Dump([$old],[qw(old)]);

if ($string ne $check) {
    print "eek!\n";
}

print "\n---\n$string---\n$check\n";
[download]

Data::Dumper's man page says:

The default output of self-referential structures can be `eval'ed, but the nested references to `$VAR'n will be undefined, since a recursive structure cannot be constructed using one Perl statement. You should set the `Purity' flag to 1 to get additional statements that will correctly fill in these references.

Ciao, Valerio

undef $old;

$old = {
         'child' => {
                      'parent' => $old,  # !!!
                      'name' => 'bob jr'
                    },
         'name' => 'bob'
       };
[download]

Obviously, the parent key is assigned the new value of $old, which is, well, undef.

Update: You want to check the Data::Dumper POD for the $Data::Dumper::Purity setting.

#!/usr/bin/perl -w
use strict;
use Data::Dumper;

my $old = {
    name => "bob",
    child => {
        name => "bob jr",
    }
};
$old->{child}{parent} = $old;

$Data::Dumper::Purity = 1;
print Data::Dumper->Dump([$old], ['$old']);

__END__
$old = {
         'child' => {
                      'parent' => {},
                      'name' => 'bob jr'
                    },
         'name' => 'bob'
       };
$old->{'child'}{'parent'} = $old;
[download]

Makeshifts last the longest.

$check = Data::Dumper->new([$old],[qw(old)])->Purity(1)->Dump
[download]

But more pertinent (as i think its unlikely that you will be dumping such structures) is that as D::D does not sort the keys of a hash you can not rely on it dumping two (for all intents and purposes) identical hashes in exactly the same way. The keys may be output in any order and thus doing a string compare on the results is not a sufficient test to determine if the two structures are the same.

HTH

--- demerphq
my friends call me, usually because I'm late....