What you want is:

my ($the_name) = $dbh->selectrow_array(
            "SELECT the_name FROM the_table WHERE id=3");
[download]

$sth = $db->prepare("SELECT the_name FROM the_table WHERE id=?");
$sth->execute(3);
my ($the_name) = $sth->fetchrow_array;
[download]

After Compline,
Zaxo

This

$sth = $db->prepare("SELECT the_name FROM the_table WHERE id=?");
$sth->execute(3);
my ($the_name) = $sth->fetchrow_array;
[download]

Can be converted into this

my ($the_name) = $dbh->selectrow_array(<<SQL, undef, 3);
SELECT the_name FROM the_table WHERE id = ?
SQL
[download]

Although it always feels a little weird using selectrow_array for a single value. But I guess that's what abstraction layers are for :)
HTH

_________
broquaint

If four statements strikes you as being a great length, then hide the length by wraping it up in a subroutine.

  sub the_name {
      my $id = shift;
      my $sth = $db->prepare("select the_name from table where id = ?"
+);
      $sth->execute($id);
      my ($the_name) = $sth->fetchrow_array();
      $sth->finish();
      return $the_name;
  }
[download]

package GS::DBIUtilities;
require Exporter;
@ISA = ("Exporter");

use DBI;

my $module_dbh;

sub
GetDBH
{

#--------------------------------------------------------------
# Connect to the amt db and return a db
#--------------------------------------------------------------

    my $db = shift;
    $module_dbh = DBI->connect("DBI:mysql:database=$db", "xxxxx", "xxx
+xx");
    return $module_dbh;
}


sub
DropDBH
{

#---------------------------------------------------------------
# Disconnect from DB
#---------------------------------------------------------------

    $module_dbh->disconnect if $module_dbh;
}


sub
InsertMultipleValues
{

#---------------------------------------------------------------
# Inserts contents of a hashref into the db table specified
#---------------------------------------------------------------

    my $dbh = shift;
    my $table = shift;
    my $Inserts = shift;

    my @cols = keys %$Inserts;
    my @vals = @$Inserts{@cols};
    my $cols = join ',', @cols;
    my $places = '?,' x @vals;
    chop $places;

    my $sth = $dbh->prepare("INSERT INTO $table ($cols) VALUES ($place
+s)") or die $dbh->errstr;
    $sth->execute(@vals) or die "$dbh->errstr : $table";
}


sub
ReplaceMultipleValues
{

#---------------------------------------------------------------
# Replaces contents of a hashref into the db table specified
#---------------------------------------------------------------

    my $dbh = shift;
    my $table = shift;
    my $Replaces = shift;

    my @cols = keys %$Replaces;
    my @vals = @$Replaces{@cols};
    my $cols = join ',', @cols;
    my $places = '?,' x @vals;
    chop $places;

    my $sth = $dbh->prepare("REPLACE INTO $table ($cols) VALUES ($plac
+es)") or die $dbh->errstr;
    $sth->execute(@vals) or die $dbh->errstr;
}


sub
FetchSingleItem
{
#---------------------------------------------------------------
# Fetch a single item from a database
#---------------------------------------------------------------

    my $dbh = shift;
    my $FetchCol = shift;
    my $table = shift;
    my $SearchCol = shift;
    my $SearchVal = shift;
   
    my $sth = $dbh->prepare("SELECT $FetchCol FROM $table WHERE $Searc
+hCol = ? LIMIT 1") or die $dbh->errstr;
    $sth->execute($SearchVal);
    my @ref = $sth->fetchrow_array;

    return $ref[0];
}


sub
InsertAndGetID
{

#---------------------------------------------------------------
# inserts an entry into a db and gets the auto_increment ID
#---------------------------------------------------------------

    my $dbh = shift;
    my $table = shift;
    my $Inserts = shift;
    my $IDCol = shift;

    $Inserts->{$IDCol} = 'NULL';
    
    $dbh->do("LOCK TABLES $table WRITE") or die $dbh->errstr;

    InsertMultipleValues($dbh,$table,$Inserts);

    $sth = $dbh->prepare("SELECT LAST_INSERT_ID() FROM $table") or die
+ $dbh->errstr;
    $sth->execute or die $dbh->errstr;
    my @ary = $sth->fetchrow_array or die $dbh->errstr;

    $dbh->do("UNLOCK TABLES") or die $dbh->errstr;
    $sth->finish;

    return $ary[0];
}


sub
FetchStar
{

#---------------------------------------------------------------
# Retrieves the whole of each row that matches the submitted
# criteria.   Returns a hashref if there is only one row,
# otherwise a ref to an array of hashes.
#---------------------------------------------------------------

    my $dbh = shift;
    my $table = shift;
    my $SearchCol = shift;
    my $SearchVal = shift;
    
    my $sth = $dbh->prepare("SELECT * FROM $table WHERE $SearchCol = ?
+") or die $dbh->errstr;
    $sth->execute($SearchVal);

    my @returns;
    while (my $ref = $sth->fetchrow_hashref) {
        push @returns, $ref;
    }

    if (@returns <= 1) {
        return $returns[0];
    }
    else {
        return \@returns;
    }
}



@EXPORT = qw/
    GetDBH
    DropDBH
    InsertMultipleValues
    ReplaceMultipleValues
    FetchStar
    FetchSingleItem
    InsertAndGetID
/;

1;#
[download]

I use only one sub to run simple SQL:

sub runSQL {
    my $sql = shift;

    if ($sql =~ /^select/i) {
        my $sth = $dbh->prepare($sql);

        if (!$sth) {
            die "Error:" . $dbh->errstr . " :: $sql\n";
        }
        if (!$sth->execute) {
              die "Error:" . $sth->errstr . " :: $sql\n";
        }
    
        my @ret;
        while (my $ref = $sth->fetchrow_hashref()) {
            push @ret, $ref;
        }
        $sth->finish();
        return \@ret;
    }
    elsif ($sql =~ /^(insert|update|delete)/i) {
            
        if (!($dbh->do($sql))) {
              die "Error:" . $dbh->errstr . " :::: $sql\n";
        }
    }
}
[download]

Pass @_ to execute() and you can use placeholders. Handy. (I'd also use a prefixed unless, but that's just me.)

My motivation was the same as yours. The DBI calls are many and varied and sometimes bulky, and the DBI manual is awfully long reading, so I just wanted my own "wrapper" module that would have a handful of always-useful, always compact methods, whose names and args are easy to remember. I seldom/never need more than what the wrapper provides, and hardly ever need to look back at the DBI man page anymore...