•Re: Strip HTML tags again


Your skill will accomplish what the force of many cannot
	PerlMonks

•Re: Strip HTML tags again

by merlyn (Sage)

on Jun 30, 2002 at 15:54 UTC ( [id://178377]=note: print w/replies, xml )

Need Help??

in reply to Strip HTML tags again

Here's an example from the eg directory in the HTML::Parser distribution:

#!/usr/bin/perl -w

# Extract all plain text from an HTML file

use strict;
use HTML::Parser 3.00 ();

my %inside;

sub tag
{
   my($tag, $num) = @_;
   $inside{$tag} += $num;
   print " ";  # not for all tags
}

sub text
{
    return if $inside{script} || $inside{style};
    print $_[0];
}

HTML::Parser->new(api_version => 3,
                  handlers    => [start => [\&tag, "tagname, '+1'"],
                                  end   => [\&tag, "tagname, '-1'"],
                                  text  => [\&text, "dtext"],
                                 ],
                  marked_sections => 1,
        )->parse_file(shift) || die "Can't open file: $!\n";;
[download]

-- Randal L. Schwartz, Perl hacker