This problem looks tailor-made for my HTML::TokeParser::Simple module, when combined with HTML::Tagset. The following test will demonstrate:

#!/usr/bin/perl -w
use strict;
use HTML::TokeParser::Simple;
use HTML::Tagset;

my $html = <<'END_HTML';
<a href="mylink">text1</a>
<this is normal text>
END_HTML

my $p = HTML::TokeParser::Simple->new( \$html );

while ( my $token = $p->get_token ) {
    next if ! $token->is_text 
              and 
              exists $HTML::Tagset::isKnown{ $token->return_tag };
    print $token->return_text;
}
[download]

Result:

text1
<this is normal text>

Cheers,
Ovid

Join the Perlmonks Setiathome Group or just click on the the link and check out our stats.

++ for the original. I'm posting an updated example because some changes to the module seem to have borked your example. This is an in place stripper--based on the one you posted--with the newer/working syntax.

sub strip_html {
    my $renew = "";
    my $p = HTML::TokeParser::Simple->new(\$_[0]);
    no warnings "uninitialized";
    while ( my $token = $p->get_token ) {
        next if ! $token->is_text
            and
            exists $HTML::Tagset::isKnown{ $token->get_tag };
        $renew .= $token->as_is;
    }
    $_[0] = $renew;
}
[download]

#!/usr/bin/perl -w

# Extract all plain text from an HTML file

use strict;
use HTML::Parser 3.00 ();

my %inside;

sub tag
{
   my($tag, $num) = @_;
   $inside{$tag} += $num;
   print " ";  # not for all tags
}

sub text
{
    return if $inside{script} || $inside{style};
    print $_[0];
}

HTML::Parser->new(api_version => 3,
                  handlers    => [start => [\&tag, "tagname, '+1'"],
                                  end   => [\&tag, "tagname, '-1'"],
                                  text  => [\&text, "dtext"],
                                 ],
                  marked_sections => 1,
        )->parse_file(shift) || die "Can't open file: $!\n";;
[download]

-- Randal L. Schwartz, Perl hacker

Have a look at HTML::Tagset it contains various lists of valid HTML tags for different sections of a document.

Update: ++ to Ovid for providing the working example below.

Thanks!!! It is the stuff I was looking for. Now I'd like to know how to use it in a 'perl' manner. Currently I have the following code (right from perlfaq):

sub strip_html {
    my $t = shift;
    $t =~ s/<(?:[^>'"]*|(['"]).*?\1)*>//gs;
    return $t;
}
[download]

Seems like I have to use %HTML::Tagset::isKnown hash, but how to apply it to my sub? I can't find any quick way...

--dda

Re: Tag filtering: a standard mechanism?

cheers

tachyon

s&&rsenoyhcatreve&&&s&n.+t&"$'$`$\"$\&"&ee&&y&srve&&d&&print

heh. i ended up writing HTML::TagFilter because tachyon shouted at me so loud. Which only does part of what you want, sadly, so I wouldn't recommend it. But i'm usefully reminded to finish the next version, which does the rest. And lots of other exciting things, i feel sure.

HTML::LinkExtor is an HTML parser that extracts links from an HTML document. The HTML::LinkExtor is a subclass of HTML::Parser. This means that the document should be given to the parser by calling the $p->parse() or $p->parse_file() methods.

I've used it successfully in the past with a lot of my parsing code.

What this is doing is finding text contained in <>'s that has a corresponding ending tag.

Here is the code ($l is the scalar holding the line of text):

if( $l =~ /<.*?>(.*?)<\/.*?>/ ) { 
    $l = $1; 
}
[download]

-----------------------------------
Frank Wiles <frank@wiles.org>
http://frank.wiles.org

Thanks, but I need a solution which 'knows' about possible HTML tags. What I need is to filter HTML from a chat message, and if someone type '<Hehe>' - it will be wiped off.

--dda

Ok, I'll try to explain. If someone types '<b>some text</b>', it should not be be displayed as a bold text in chat window, and displaying the HTML source is not a good idea too. I just have to strip all tags from the line.

And '<some text>' should not be stripped. All regexp-based solutions will strip this too. I'm still looking for regexp-based stuff that will use %HTML::Tagset::isKnown hash to filter out only correct HTML tags.

--dda

look up the POD (or your preferred docs) for HTML::Tagset
cite: "hashset %HTML::Tagset::isKnown
This hashset lists all known HTML elements."
So you've got to compare your match with that list ...

Have a nice day
All decision is left to your taste

Addendum

Look through the previous suggestions as well. Try it at least and ask again if you get an error or get otherwise stuck. :-)