There is now also Ref::Util which avoids the need to compare the result against a string (which itself might contain a typo). So, instead of

use Scalar::Util 'reftype';
if (reftype ($foo) eq 'ARAY') { # spot the typo
    do_something ();
}
[download]

which would silently fail to do anything even if $foo were an arrayref, we can now say

use Ref::Util 'is_arrayref';
if (is_arrayref ($foo)) {
    do_something ();
}
[download]

which would throw a compile-time error if we had a similar typo in the function name.

Ref::Util also uses the XS implementation (if installed) which makes it fast. It has no dependencies beyond Exporter. There are plenty of other goodies in this module which you can find in the documentation.

Use the ref function. It returns false if its argument is not a reference, and otherwise returns a string describing the referenced object. For example, in the case of an unblessed hash, it returns the string "HASH".

if ( ! ref($x) ) {
    # Not a reference
}
elsif ( UNIVERSAL::isa($x,'HASH') ) {
    # Reference to a hash
}
elsif ( UNIVERSAL::isa($x,'ARRAY') ) {
    # Reference to an array
}
elseif ( UNIVERSAL::isa($x,'SCALAR') || UNIVERSAL::isa($x,'REF') ) {
    # Reference to a scalar
}
elsif ( UNIVERSAL::isa($x,'CODE') ) {
    # Reference to a subroutine
}
[download]

The Scalar::Util module provides a function reftype for this. It's somewhat more robust than the built-in ref function.

use Scalar::Util 'reftype';

my $reftype = reftype $x;

if ( !defined $reftype ) {
    print "\$x is not a reference.\n";
}
elsif ( $reftype eq 'HASH' ) {
    # do something with %$x
}
elsif ( $reftype eq 'ARRAY' ) {
    # do something with @$x
}
elsif ( $reftype eq 'SCALAR' ) {
    # do something with $$x
}
else {
    # do something else
}
# ...
[download]

Note that Scalar::Util::reftype behaves almost like the built-in ref, except when an object is passed.

use Scalar::Util 'reftype';
$a=\$b;
print reftype($a),"\n"; #SCALAR
print ref($a),"\n";     #SCALAR
bless $a, "BOGUS";
print reftype($a),"\n"; #SCALAR
print ref($a),"\n";     #BOGUS
[download]

And that is exactly why I chose to use it!