What you're trying to do, essentially, is calculate set union and/or set difference (depending on how you look at it) using arrays.

This is covered in Perl FAQ section 4. There are variations in the Perl Cookbook, and people have posted questions and code snippets here in the monastery. You can also snoop around the Categorized Questions and Answers. One of those should provide answers.

use strict;

my @a=qw(a b c d);
my @b=qw(b a e f);

# this does exactly what your pair of 'for' loops 
# did...
my @m = map {
    my $x = $_;
    grep { /^$x$/ } @b;      
} @a;
 
print @m;
print "\n";
[download]

ab
[download]

use strict;

my @a=qw(a b c d);
my @b=qw(b a e f);

my %h;
my @m = map {$h{$_}++ ? $_ : ()} (@a, @b);
 
print @m;
print "\n";
[download]

$"=q;grep;;$,=q"grep";for(`find . -name ".saves*~"`){s;$/;;;/(.*-(\d+)
+-.*)$/;
$_=["ps -e -o pid | "," $2 | "," -v "," "];`@$_`?{print"+ $1"}:{print"
+- $1"}&&`rm $1`;
print$\;}
[download]

Not to try and throw you in over your head, but if the context of your program is more related to set operations than to array properties, you may want to have a look at Set::Scalar. This module will allow you do something as simple as:

use Set::Scalar ;

my $s = Set::Scalar->new( 'a', 'b', 'c', 'd' ) ;
my $t = Set::Scalar->new( 'a', 'e', 'c', 'o' ) ;

my $u = $s->intersection( $t ) ;

print $u, "\n" ;
[download]

(a c)
[download]

#!/usr/bin/perl -w

use strict;
use Quantum::Superpositions;

my @array1 = qw( 0 2 4 6 8 10 12 14 16 18 20 );
my @array2 = qw( 0 5 10 15 20 );

if(any(@array1) eq any(@array2)) {
    print "A match!\n";
}
else {
    print "Nope, no match\n";
}
[download]

 #!/usr/bin/perl -w

use strict;

# Set up the arrays
my @array1 = qw(a b c d);
my @array2 = qw(b a e f);

# Create the hash, based on array1
my %hash;
foreach (@array1) {$hash{$_} = 1;}

# Loop through array2 looking for matches
foreach (@array2) {
    if ($hash{$_}) {print $_, "\n"}
}
[download]

#!/usr/bin/perl -w

use strict;

my @array1 = qw[a b c d e];
my @array2 = qw[a n o t h e r];

my %count;
foreach my $element (@array1, @array2) {
  $count{$element} += 1;
}
foreach my $key (keys %count) {
  print "$key appears in both arrays\n" if $count{$key} == 2;
}
[download]

$ ./foo.pl 
a appears in both arrays
e appears in both arrays
[download]

#!/usr/bin/perl -w

use strict;

my @array1 = qw[a b c d e];
my @array2 = qw[t e s t d a t a];

my @sort1 = sort @array1;
my @sort2 = sort @array2;

while (@sort1 && @sort2) {
  if ($sort1[0] eq $sort2[0]) {
    my $match = $sort1[0];
    while (@sort1 && $sort1[0] eq $match) { shift @sort1; }
    while (@sort2 && $sort2[0] eq $match) { shift @sort2; }
    print "$match is in both arrays\n";
  } elsif ($sort1[0] lt $sort2[0]) {
    shift @sort1;
  } else {
    shift @sort2;
  }
}
[download]

$ ./bar.pl 
a is in both arrays
d is in both arrays
e is in both arrays
[download]

@array1 = (1,2,3,4,5);
@array2 = (2,4,6,8,10);

%map2 = map {$_ => 1} @array2;

@intersection = grep ($map2{$_}, @array1);

print "@intersection\n";
[download]

--
Steve Marvell