Re: read between two strings


Clear questions and runnable code get the best and fastest answer
	PerlMonks

Re: read between two strings

by Rhose (Priest)

on May 16, 2002 at 15:07 UTC ( [id://167022]=note: print w/replies, xml )

Need Help??

in reply to read between two strings

You could use the flip-flop operator to skip lines which are not between the %%Atom Coords and %%End Frame markers. Maybe something like this?

#!/usr/bin/perl -w
use strict;

while (<DATA>)
{
  
  #-- Skip lines not in the section to be processed
  next unless /^%%Atom Coords/../^%%End Frame/;

  #-- Skip the section markers
  next if (/^%%Atom Coords/ or /^%%End Frame/);

  #-- Parse lines...
  print;
}

__DATA__
%%Atom Coords
-1.13 12.16 6.15
%%End Frame

more stuff...

and more stuff...

%%Atom Coords
-2.26 24.32 12.30
%%End Frame
[download]

Comment on Re: read between two strings Download Code

Replies are listed 'Best First'.

•Re: Re: read between two strings
by merlyn (Sage) on May 16, 2002 at 15:13 UTC

  #-- Skip lines not in the section to be processed 
  next unless /^%%Atom Coords/../^%%End Frame/; 
 
  #-- Skip the section markers 
  next if (/^%%Atom Coords/ or /^%%End Frame/);
[download]

  my $inrange = /^%%Atom Coords/../^%%End Frame/; 
  next unless $inrange;
  next if $inrange == 1 or $inrange =~ /E/; # skip first and last item
+ of range
[download]

-- Randal L. Schwartz, Perl hacker

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom