Put simply, you'll have to read in the file, process it, and then save it back out.

my( $filename, $arg1, $arg2 ) = @ARGV;

open IN, '<', $filename or die;
my @contents = <IN>;
close IN;

@contents = grep !/^$arg1,$arg2,/, @contents;

open OUT, '>', $filename or die;
print OUT @contents;
close OUT;
[download]

This will force the first and second field in the file to match exactly the first and second arguments that you pass in.

If you know the exact line number you want to "delete," try this one-liner:
perl -ni -e "print unless $. == $linenum" <filename>

Here's a command-line one-liner:

perl -p -i.bak -e "next if /^sandwich,hamburger,/" comma.file
[download]

You could wrap this in a batch script or shell alias to facilitate the substitution of parameter values.

Alternatively:

perl -n -i.bak -e "print unless /^sandwich,hamburger,/" comma.file
[download]

This actually won't delete the line, since the implied print gets done as part of the continue portion of the loop, which happens even after a next.

To delete, I think you'd need to substitute the matched line with null, but given that, I think the more obvious way is to switch to explicitly printing, like:

perl -i -n -e 'print if not /^sandwich,hamburger,/i' comma.file
[download]

This one-liner also takes advantage of the -i switch to edit the file in place, which seemed to be desired in the original question.

Another alternative is to use Tie::File. This lets you treat a file as a regular array variable. This is very convenient because it is easy to understand what is going on, as long as you are familiar with perl arrays.

use Tie::File;

my( $file_name, $arg1, $arg2 ) = @ARGV;

# open the file with tie
tie my @file_lines, 'Tie::File', $file_name or die;

# delete the first line
shift @file_lines;

# filter out lines containing 'sandwich'
@file_lines = grep !/^$arg1,$arg2,/, @file_lines;

# close the file with untie.
# IMPORTANT: always untie when you are done!
untie @file_lines or die "$!";
[download]

Update: Note that perl does not actually load the file into the array. It only appears to do so.

local @ARGV = ("input.file");
while(<>)
{
   s/pattern//; # remove line matching pattern
   print;
   last if eof;
}
[download]

Originally posted as a Categorized Answer.