package ConfigIni;

use strict;
use warnings;

use Config::IniFiles;
use Text::CSV;
use Carp;

our $VERSION = '0.01';
    
sub new
{
    my $proto = shift;
    my $class = ref($proto) || $proto;
    my $self = {};
    
    $self->{file} = shift || "";
    $self->{ini} = new Config::IniFiles( -file => $self->{file}, -nocase => 1);
    return undef if not defined $self->{ini};

    bless $self, $class;
    return $self;
}

sub get_ini_val
{
    #return a single valued parameter
    my $self = shift;
    my $section = shift || croak "must provide section to get_ini_val";
    my $param = shift || croak "must provide param to get_ini_val";
    my $default = shift; #optional default value

    my $val = $self->{ini}->val($section,$param);
    if (!defined $val)
    {
        $val = $default; #undef if default no provided
    }
    return $val;
}

sub get_ini_val_multi
{
    #return a list of a multi-valued parameter
    my $self = shift;
    my $section = shift || croak "must provide section to get_ini_val";
    my $param = shift || croak "must provide param to get_ini_val";
    my $default = shift; #array ref to optional default values

    my $values = $self->{ini}->val($section,$param);
    my @values = ();
    if (defined $values)
    {
        my $csv = Text::CSV->new();
        my $status = $csv->parse($values);
        croak "error parsing $section, $param, with value = $values" unless $status;
        @values = $csv->fields();
    }
    else
    {
        @values = $default ? @{$default} : ();
    }
    return @values;
}

1;