fetchrow_array() returns an array. If you assign it like:
my $count = $sth->fetchrow_array();
$count will always equal [the] scalar context of the array

Therefore, $count will be the scalar context of the list. Lists in scalar context evaluate to the their rightmost element. If you actually wanted the behavior you describe above, you'd need to put it inside a "list bag", more commonly called an array:

my $count = @{[ $sth->fetchrow_array() ]};
[download]

-Blake

The most obvious example of this is localtime() whose return values in scalar and list context have little to do with one another. Another example happens to be fetchrow_array()

From the DBI pod:

In a scalar context, fetchrow_array returns the value of the first field. An undef is returned if there are no more rows or if an error occurred. Since that undef can't be distinguished from an undef returned because the first field value was NULL, you should exercise some caution if you use fetchrow_array in a scalar context.

The moral of the story is that the behavior of a subroutine in scalar context can't be determined from its list context return value.

Here are three subs that return the same values in list context, but behave differently in scalar context:

#!/usr/bin/perl -wT
use strict;

sub test1 {
  return @{[ qw(A B C) ]};
}

sub test2 {
  return qw(A B C);
}

sub test3 {
  return wantarray ? qw(A B C) : 'I like jellybeans';
}

print "List context\n",
      "  test1: ", join(', ',test1()), "\n",
      "  test2: ", join(', ',test2()), "\n",
      "  test3: ", join(', ',test3()), "\n",
      "\nScalar context\n",
      "  test1: ", scalar test1(), "\n",
      "  test2: ", scalar test2(), "\n",
      "  test3: ", scalar test3(), "\n";

=OUTPUT
List context
 test1: A, B, C
 test2: A, B, C
 test3: A, B, C

Scalar context
 test1: 3
 test2: C
 test3: I like jellybeans
[download]

-Blake

#!/usr/bin/perl

my @array = qw(fred ethel ricky lucy);
my $scalar = @array;

print $scalar, "\n";

exit;
[download]

perl seems to be using a character set that creates the numeral one in a glyph that's just like the US English numeral four. Odd.

SELECT COUNT(*) returns a single value. fetchrow_array returns an array. If you put the two together, you'll get the row count returned in a single-element array. Here's the correct example:

my @array  = (42);
my $count  = @array;
my ($elem) = @array;
print "$count element, which is ($elem)\n";
[download]

Update: Oops, it does return a list. The specification even says that it returns the value of the first field in scalar context (a little wantarray action). I'd have missed the boat completely if it didn't go on to warn about calling it in scalar context, though I didn't read that initially.

Hey everyone, look over there => !

Actually, fetchrow_array returns a list not an array. It makes a big difference in this discussion. Consider the following code:

#!/usr/bin/perl -wT
use strict;

my @array       = (42);

my $array_count = @array;     # array in scalar context
my $list_count  = (42);       # list in scalar context
my $sub_count   = testsub();  # list or array????

print "Array in scalar context:   $array_count\n",
      "List in scalar context:    $list_count\n",
      "Subs rv in scalar context: $sub_count\n";

sub testsub {
  # does this return a list or an array????
  return (42);
}

=OUTPUT
Array in scalar context:   1
List in scalar context:    42
Subs rv in scalar context: 42
[download]

The array evaluates to its number of elements, but the list evaluates to its rightmost member - in this case 42. The return value from the subroutine is actually a list not an array, which explains why $sub_count == $list_count == 42.

-Blake