Suppose you have a program consisting of just >. What happens to it when you run your code:

1. s/>/\t\t++k;\n/g; transforms it into \t\t++k;\n
2. s/</\t\t--k;\n/g; does nothing, it's still \t\t++k;\n
3. s/\+/\t\t++*k;\n/g; transforms each + present in the program into \t\t++*k;\n, leaving you with \t\t\t\t++*k;\n\t\t++*k;\nk;\n

my %sub = {
 ">" => "\t\t++k;\n",
 "+" => "\t\t++*k;\n",
 ... # fill as needed
}
[download]

s/(.)/$sub{$1}/ge
[download]

A faster, but less elegant solution would be to replace + and - first, then consider other characters which might produce their own [+-].

my %sub = {
 ">" => "\t\t++k;\n",
 "+" => "\t\t++*k;\n",
 ... # fill as needed
 }
[download]

The hash initialization statement above should use parentheses and not curlies:
    my %sub = ( ... );

s/(.)/$sub{$1}/ge

Also note that the  /e modifier is not needed in this substitution (although it does no harm except to burn some time) because  $sub{$1} is already a scalar that can be interpolated into a string.

---

Give a man a fish:  <%-{-{-{-<

Thanks for the corrections. I should have noted that my reply was prepared on a mobile device and mostly untested.

Thank you. Because this is a rough translator, I fixed this using non elegant method.

        s/</\t\tAAk;\n/g;
        s/>/\t\tBBk;\n/g;
        s/\+/\t\tAA*k;\n/g;
        s/\-/\t\tBB*k;\n/g;
        s/\./\t\tputchar(*k);\n/g;
        s/\,/\t\t*k = getchar();\n/g;
        s/\[/\twhile (*k) {\n/g;
        s/\]/\t}\n/g;
        s/A/+/g;
        s/B/-/g;
[download]

You seem to also want indentation with "\t", which means you need to keep count of the loop levels.

Here a much easier to maintain code, looping over a split and keeping track of indentation.

And you can easily adapt this code to emit other languages - like Perl° - too, without worrying about polluted input.

use strict;
use warnings;
#use Data::Dump qw/pp dd/;
#use feature qw/say/;

my @table = split /\n/, <<'__TABLE__';
>    ++k;
<    --k;
+    ++*k;
-    --*k;
.    putchar(*k);
,    *k = getchar();
[    while (*k) {
]    }
__TABLE__

my %trans = map { split/\s+/, $_, 2 } @table;
#pp \%trans;



my $bfs   = '+[--[--]->+++<]>+.---';
my $level = 0;

for my $atom ( split //, $bfs ) {

    $level-- if $atom eq "]";
    print "\t" x $level;
    $level++ if $atom eq "[";
    
    print $trans{$atom};
    #print "\t\t\t// was '$atom'";         # debug
    print "\n";
}
[download]

++*k;
while (*k) {
    --*k;
    --*k;
    while (*k) {
        --*k;
        --*k;
    }
    --*k;
    ++k;
    ++*k;
    ++*k;
    ++*k;
    --k;
}
++k;
++*k;
putchar(*k);
--*k;
--*k;
--*k;
[download]

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery FootballPerl is like chess, only without the dice}

update

°) which would allow you to use the perldebugger to step thru BF code.

update

changed code to improve readability

Please show us the expected output and what you got for a short example input.

See also SSCCE

Update

After reading brainfuck I'm understanding your problem is that you are inserting + symbols as c-code which is replaced later as BF code.

Translating linear code with a series of global s///g substitutions rarely works, because you are running over your own output.

But Anonymous Monk has already given you an excellent answer in the meantime.