I'm currently reading the book Higher Order Perl and I'm on the section where it covers memoization. The book says a single multiplication won't be improved on by memoization because of the overhead involved and because multiplication is already fast. I'm surprised that your lookup with ord() and substr() is faster than a single multiplication. The only difference I see is that my function is using a float constant and the ord() and substr() don't need to do float calculations.

#!/usr/bin/env perl
use warnings;
use strict;
use Benchmark 'cmpthese';

my $lookup = join '', map{ chr( $_ / 255 * 100 ) } 0 .. 255;
my $const = 100 / 255;

cmpthese(-2, {
    lookup => sub {
        my @output = map { ord( substr $lookup, $_, 1 )} 0 .. 255;
    },
    calc   => sub {
        my @output = map {$_ / 255 * 100} 0 .. 255;
    },
    calc2   => sub {
        my @output = map {$_ * $const} 0 .. 255;
    },
});

my @output1 = map { ord( substr $lookup, $_, 1 )} 0 .. 5;
my @output2 = map {$_ * $const} 0 .. 5;
print "@output1\n";
print "@output2\n";
__END__

# Results on my machine (v5.22.1 built for MSWin32-x64-multi-thread):
          Rate   calc  calc2 lookup
calc   12009/s     --   -24%   -31%
calc2  15753/s    31%     --    -9%
lookup 17376/s    45%    10%     --
0 0 0 1 1 1
0 0.392156862745098 0.784313725490196 1.17647058823529 1.5686274509803
+9 1.96078431372549
[download]

the ord() and substr() don't need to do float calculations.

In this$_ * $const first the integer in $_ is promoted to a double (to match the type of $const), then the multiplication is done, and then (to make it useful for the OP though you aren't doing it here) the result needs to be converted (trunc'd) back to an integer. (If you added back that necessity, the difference would be more marked.)

Runtime memoization and look up using a hash (per the Memoize module) would be much slower because each input integer needs to be be converted to a string, then that string must be hashed, then taken modulo the hash size (which must be looked up, then that table entry inspected, and (potentially) a linear search of an array performed, before the value is found.

The lookup essential consists of a direct index and done.

For the OPs purpose, an array lookup would probably be even quicker:

#! perl -slw
use strict;

my @lookup = map{ int( $_ / 255 * 100 ) } 0 .. 255;

print "$_ :: ", $lookup[ $_ ] for 0 .. 255;
[download]

---

With the rise and rise of 'Social' network sites: 'Computers are making people easier to use everyday'

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority". The enemy of (IT) success is complexity.

In the absence of evidence, opinion is indistinguishable from prejudice. Suck that fhit

Thanks for the explanation about the float conversions and hash memoization.

The array lookup is quite a bit faster than the string index. I didn't see in the OP that the result had to be integers. The OP showed floats as the output. Edit: The array lookup method will work equally well with either floats or ints since the int() function is not in the part that does the lookup.

#!/usr/bin/env perl
use warnings;
use strict;
use Benchmark 'cmpthese';

my $lookup = join '', map{ chr( $_ / 255 * 100 ) } 0 .. 255;
my @lookup = map{ int( $_ / 255 * 100 ) } 0 .. 255;
my $const = 100 / 255;

cmpthese(-2, {
    lookup => sub {
        my @output = map { ord( substr $lookup, $_, 1 )} 0 .. 255;
    },
    calc   => sub {
        my @output = map {$_ / 255 * 100} 0 .. 255;
    },
    calc2   => sub {
        my @output = map {$_ * $const} 0 .. 255;
    },
    arraylookup   => sub {
        my @output = map { $lookup[ $_ ] } 0 .. 255;;
    },
});

my @output1 = map { ord( substr $lookup, $_, 1 )} 0 .. 5;
my @output2 = map {$_ * $const} 0 .. 5;
print "@output1\n";
print "@output2\n";
__END__

# Results on my machine (v5.22.1 built for MSWin32-x64-multi-thread):
               Rate        calc       calc2      lookup arraylookup
calc        11990/s          --        -25%        -31%        -47%
calc2       15929/s         33%          --         -9%        -30%
lookup      17496/s         46%         10%          --        -23%
arraylookup 22838/s         90%         43%         31%          --
0 0 0 1 1 1
0 0.392156862745098 0.784313725490196 1.17647058823529 1.5686274509803
+9 1.96078431372549
[download]