Something changed in 5.22. $My::{$symbol} can return a code reference or -1 instead of a glob.

The following is therefore needed:

sub get_code_ref_by_fqn {  # Fully qualified name
   my ($fqn) = @_;

   my @pkg_name_parts = split /::/, $fqn;
   my $symbol = pop(@pkg_name_parts);

   my $pkg = \%::;
   for (@pkg_name_parts) {
      $pkg = $pkg->{$_.'::'}
         or return undef;
   }

   my $glob_or_code = $pkg->{$symbol}
      or return undef;

   return $glob_or_code if ref($glob_or_code);
   return undef if ref(\$glob_or_code) ne 'GLOB';
   return *$glob_or_code{CODE};
}
[download]

But you know what, let's just leave those dirty details to Perl.

sub get_code_ref_by_fqn {  # Fully qualified name
   my ($fqn) = @_;
   no strict qw( refs );
   return undef if !defined(&$fqn);
   return \&$fqn;
}
[download]

Above tested using

use 5.012;
use warnings;

sub Foo::Bar::y;
sub Foo::Bar::z { }

say get_code_ref_by_fqn('Foo::Bar::x') // '[undef]';
say get_code_ref_by_fqn('Foo::Bar::y') // '[undef]';
say get_code_ref_by_fqn('Foo::Bar::z') // '[undef]';
[download]

Main is %:: (or %main:: (or %main::main:: (...))) instead of %My::.

I know that.

But I want one expression to determine the condition, I want to avoid (for reasons of pure idiocy) to have an extra assignment...

So something like

print defined *main::{$symbol}->*{CODE} ? "yep": "nope";
[download]

But I cannot do it...