Probably not the best way, but this works:

#!perl

use strict;
use warnings;
use JSON::PP;

my $json;
{
    local $/ = undef;
    open my $fh, '<', 'in.json';
    $json = <$fh>;
    close $fh;
}

my $final;
my $decoded = decode_json($json);

for my $ob ( @{$decoded->{observations}} ) {
    for my $status ( @{$ob->{status}} ) {
        for my $elem ( sort ( keys ( %{$status} ) ) ) {
            print $elem . "=" . $status->{$elem} . "\n";
        }
    print "\n";
    }
}
[download]

and outputs ...

info=%(MinorFrameCnt)%
kind=I
path=_L7=
stat=O

info=%(Offset)%
kind=I
path=_L2=
stat=O

info=%(Period)%
kind=I
path=_L1=
stat=O

info=%(_L3)% = _L8
kind=I
path=_L6=-1
stat=O

info=_L3 = %(_L8)%
kind=I
path=_L6=-2
stat=O
[download]

Thank you for you answer, actually it worked great

But now i want to only search for the "kind" tag and here is what i did:

for my $ob ( @{$decoded->{observations}} ) {
    for my $status ( @{$ob->{status}} ) {
      for my $kind (@{$status->{info}}){
           for $elem ( sort ( keys ( %{$kind} ) ) ) {
            $final1 .= $kind->{$elem} .",";
        }
      }
     
    }
}
[download]

I am getting an error that says that Cant use string (...) as an ARRAY ref while "stricts refs" in use at...

I think that is something related to deference, but i am not sure how to solve it, could you help me?

Regards

You seem to think that  $kind is a hash reference, but it isn't; it's a string, and strings (a.k.a. "symbolic references") can't be dereferenced under strict 'refs'. It's important to know the nature of the data you're dealing with. To visualize the type and value (update: and structure!) of data, use a module like Data::Dumper (which is core, so it should already be installed), or Data::Dump (which I like more, but which is not core). So maybe something like

use Data::Dumper;
...
for my $kind (@{$status->{info}}){
    print Dumper $kind;
    ...
    }
[download]

to get started. Once you know where you are, it will be easier to see the way forward.

---

Give a man a fish:  <%-{-{-{-<

How about just using:

  print $elem . "=" . $status->{$elem} . "\n" if ( $elem eq 'kind' );
[download]

instead of the original print statement?

Also see AnomalousMonk post above Re^3: Iterate JSON File about Data::Dumper.

G'day mijares93,

Welcome to the Monastery.

[Sorry, I'm a little late to the party on this one: I'm catching up after some travelling.]

The data returned from decode_json is typically a complex data structure and you can access its internal parts quite easily. Consider this short script:

#!/usr/bin/env perl

use strict;
use warnings;
use autodie;

use JSON;

my $json_file = 'pm_1219718_data.json';
my $json_text = do { open my $fh, '<', $json_file; local $/; <$fh> };
my $perl_data = decode_json $json_text;

for (@{$perl_data->{observations}[0]{status}}) {
    print "$_->{path}\n"
}
[download]

Output:

_L7=
_L2=
_L1=
_L6=-1
_L6=-2
[download]

The "$json_file" is what you posted plus

  ]
}
[download]

to close the "observations" array (with the ']') and the JSON object as a whole (with the '}').

"... I am new to Perl ..."

Here's some suggested reading:

• perlintro -- Perl introduction for beginners
• perldsc -- Perl data structures intro
• JSON
• Perl Programming Documentation - I recommend you bookmark this one and refer to it often
• MetaCPAN - I recommend you bookmark this one and refer to it as needed