The latest version of Regexp::Common::net is said to support IPv4 and IPv6 IP addresses, but I cannot say how complete the support is for IPv6. See Regexp::Common for instructions on how to use the  net (and other) module extension(s); it's slightly roundabout.

use strict;
use warnings;
use feature "say";


while (<DATA>){
    my @ips = m/\(([\d\.:]+)[\s<>]*([\d\.:]+)?[\s<>]*([\d\.:]+)?\)/;
    $_ and say "$.  >$_<" for @ips;
}

__DATA__
email
(209.85.208.68)
(172.217.194.27 < 209.85.208.68)
(172.217.194.27 < 2001:4860:4860:0:0:0:0:8888)
(2001:4860:4860:0:0:0:0:8888)
(2001:4860:4860:0:0:0:0:8888 < 2001:4860:4860::8844)
(2001:4860:4860:0:0:0:0:8888 < 172.217.194.27)
(2001:4860:4860:0:0:0:0:9999 < 172.217.194.29 Not terminated by close 
+paren
Sometimes, it appears in this way too. It may have IPV6 as well.
(172.217.194.27 < 172.217.194.27 < 209.85.208.68)
Anyway, I stared with below. It won't fulfill. It can catch ipv
[download]

2  >209.85.208.68<
3  >172.217.194.27<
3  >209.85.208.68<
4  >172.217.194.27<
4  >2001:4860:4860:0:0:0:0:8888<
5  >2001:4860:4860:0:0:0:0:8888<
6  >2001:4860:4860:0:0:0:0:8888<
6  >2001:4860:4860::8844<
7  >2001:4860:4860:0:0:0:0:8888<
7  >172.217.194.27<
10  >172.217.194.27<
10  >172.217.194.27<
10  >209.85.208.68<
[download]

Thanks for your reply.

IPV6 have characters as well. see below stuffs

2404:6800:4003:c04::5e

2600:3c00::f03c:91ff:fedf:f016

So, In YOUR below code, \d can be replaced with \w

 my @ips = m/\(([\w\.:]+)[\s<>]*([\w\.:]+)?[\s<>]*([\w\.:]+)?\)/;

\w Matches any letter, digit or underscore. Equivalent to a-zA-Z0-9_

it's greedy isn't it ? anyway, Thanks for your effort.

I stared with below. It won't fulfill. It can catch ipv4
 [\(\d+\.\d+\.\d+\.\d+ \<\)]+

One big character class like this is not the way to match structured substrings. This class is equivalent to  [()\d. +<]+ which will match '12345' or '.+.+.+.' or '()(()((()' as well as any dotted decimal IPv4 address, valid or otherwise. Please see perlre and perlretut on the general topic of "character class(es)" (and also perlrecharclass).

The following works (or seems to) for IPv4 dotted decimal addresses only, but it should be fairly easy to extend the  $rx_IPv4_dd regex to include IPv6 using the latest Regexp::Common::net. Needs Perl version 5.10+ for the  (?|pattern) "branch reset" extension. Needs many more test cases.

c:\@Work\Perl\monks>perl -wMstrict -le
"use 5.010;
 ;;
 use Test::More 'no_plan';
 use Test::NoWarnings;
 ;;
 use Regexp::Common qw(net);
 ;;
 my $rx_IPv4_dd = qr{ (?<! \d) $RE{net}{IPv4} (?! \d) }xms;
 my $rx_arrow   = qr{ \s+ < \s+ }xms;
 ;;
 VECTOR:
 for my $ar_vector (
   'all these contain one or more IPv4 addresses',
   [ 'x (209.85.208.68) x (172.217.194.27 < 123.23.34.45) x',
     '209.85.208.68', '172.217.194.27', '123.23.34.45',
     ],
   [ ' < 209.85.208.68) x (172.217.194.27 < 123.23.34.45) x',
     '172.217.194.27', '123.23.34.45',
     ],
   [ 'x (1.2.3.4) x (9.8.7.6 < 5.6.7.8) x',
     '1.2.3.4', '9.8.7.6', '5.6.7.8',
     ],
   'none of these should match',
   [ '', ],  [ 'x', ],  [ '123', ],
   [ '209.85.208.68 (999.12.23.999) (12.23.34.45 98.76.54.32)', ],
   ) {
   if (not ref $ar_vector) {
     note $ar_vector;
     next VECTOR;
     }
   ;;
   my ($str, @expected) = @$ar_vector;
   ;;
   my @got = $str =~ m{
     (?|
       (?: [(] ($rx_IPv4_dd) (?= (?: $rx_arrow $rx_IPv4_dd)? [)] ) )
       |
       (?: \G (?! \A) $rx_arrow ($rx_IPv4_dd) [)] )
     )
     }xmsg;
   is_deeply \@got, \@expected, qq{'$str' -> (@expected)};
   }
 ;;
 done_testing;
 ;;
 exit;
"
# all these contain one or more IPv4 addresses
ok 1 - 'x (209.85.208.68) x (172.217.194.27 < 123.23.34.45) x' -> (209
+.85.208.68 172.217.194.27 123.23.34.45)
ok 2 - ' < 209.85.208.68) x (172.217.194.27 < 123.23.34.45) x' -> (172
+.217.194.27 123.23.34.45)
ok 3 - 'x (1.2.3.4) x (9.8.7.6 < 5.6.7.8) x' -> (1.2.3.4 9.8.7.6 5.6.7
+.8)
# none of these should match
ok 4 - '' -> ()
ok 5 - 'x' -> ()
ok 6 - '123' -> ()
ok 7 - '209.85.208.68 (999.12.23.999) (12.23.34.45 98.76.54.32)' -> ()
1..7
ok 8 - no warnings
1..8
[download]

Perl probably has a module for that: Regexp::IPv4 Regexp::IPv6

More than one obviously. This one (Paranoid) worked fine for me in some log parsing scripts: Paranoid::Network::IPv4 Paranoid::Network::IPv6

Hmm, Many thanks for your INPUT. Really profitable for me,

Here I TEST it with below code

#!/usr/bin/perl
use strict;
use warnings;
use Regexp::IPv4 qw($IPv4_re);
use Regexp::IPv6 qw($IPv6_re);

my $ipv4_address = "192.168.0.10";
my $ipv6_address = "2600:3c00::f03c:91ff:fedf:f016";
 
$ipv4_address =~ /^$IPv4_re$/ and print "IPv4 address\n";
 
$ipv6_address =~ /^$IPv6_re$/ and print "IPv6 address\n";
[download]

Hmm. It Works

If a group could contain an inner parenthesized group then you may wish to use greedy patterns instead.

If this is an issue, I would prefer to use Regexp::Common::Balanced.
Bill

This "sundial" guy has been here for how many years? and he still doesn't know that <tt>...</tt> is not the way to mark off code. Dumbshit.