package dbLoader;

use Carp;
use Data::Dumper;
use DBI;
use Scalar::Util;
use strict;
use warnings;
use feature 'state';

    sub import {
        my $self=shift;
        return;
        }; # import:

my $KNOWN_PACKAGES_HREF;
my ($DBH,$STH);

{ # INTERNALS:
    sub _dbLoader {
        my (undef,$path_S)=@_;

        s{[/\\]}{::}g, s{\.pm$}{}
            for (my $package_s=$path_S);

        return # unless the package is in the this library
           unless (exists $KNOWN_PACKAGES_HREF->{$package_s});
        warn Data::Dumper->Dump([\$path_S,\$package_s],[qw(*path *package)]),' ';

        my $body_sref;
        eval {
            $STH->execute($package_s);
            if(my $value_aref=$STH->fetchrow_arrayref()) {
                chomp($value_aref->[0]);
                $body_sref=\$value_aref->[0];
                warn "fetched - ",Data::Dumper->Dump([$body_sref],[qw(*body)]),'';
                $INC{$path_S}="DBI:Pg:$path_S";
                };
            };
        if (my $error=$@) {
            Carp::confess $@;
            }
        elsif (!defined $body_sref) {
            return;
            }
        else {
            open my $fh,'<',$body_sref
                or Carp::confess "Couldn't open string for reading! $!";
            return (
                $body_sref,
                );
            };
        }; # _dbLoader:

    } # INTERNALS:

BEGIN {
    eval {
        $DBH=DBI->connect('dbi:SQLite:Library.sqlite','','',{ PrintError=>1, RaiseError=>1 });

        # Create a (global) hashref of packages/prefixes
        $STH=$DBH->prepare(<<"__SQL__");
            SELECT package FROM packages;
__SQL__
        $STH->execute();
        my $field_aref=$STH->{NAME_lc};
        while (my $value_aref=$STH->fetchrow_arrayref()) {
            my %_h;
            @_h{@$field_aref}=@$value_aref;
            $KNOWN_PACKAGES_HREF->{$_h{package}}=undef;
            };
        $STH->finish();
        warn Data::Dumper->Dump([\$KNOWN_PACKAGES_HREF],[qw(*KNOWN_PACKAGES)]),' ';
        # Statement handle for fetching source(s)
        $STH=$DBH->prepare(<<"__SQL__");
            SELECT body FROM packages WHERE package = ?;
__SQL__
        warn "SELECT prepared";
        unshift @INC,\&_dbLoader;
        warn "Prepended \&_dbLoader to \@INC";
        };
    if (my $error=$@) {
        Carp::confess $@;
        };
    }; # BEGIN:
END {
    print STDERR sprintf("%40s\t%s\n",$_,$INC{$_})
        for (sort grep { $INC{$_} !~ m{^([A-Za-z]:|/)}} keys %INC);
    }; # END:

    1;