Your approach of testing all 9000 files against your list can be made to work but there is a simpler alternative. You can use Perl's file tests to check the existence of each of the 300 files in your list given the path. If the file exists then do some function on it. In this example I'm using -e to test existence of the file.

use warnings;
use strict;

my $path = "path/to/folder/with/my/files";

my @list = qw( a b c d );

foreach my $file ( @list ){
    print "found $file\n" if -e "$path/$file";
}
[download]

A suggestion to save yourself a lot of struggling is to start with something small and get it working before adding the next step to it. Get the part working that reads your list of 300 files first. Once you can print it back out to the console with one file per array element then check for the existence of each file and print if found. Then keep adding small steps. You wouldn't try to build a whole building at once and then fix it so why try that with a program.

Hello oxalate,

Here is a tip regarding this section of the code:

foreach my $i (@array)      
        {
        if(grep @array[$i], @files)
            {
            my $match = (grep @array[$i], @files);
[download]

First of all, $i is being set to the actual filename, not your array index. Thats why nothing seems to be working properly. Try this to see what I mean:

$ perl -we '
my @array = qw( file1 file2 file3 );
foreach my $i (@array) {
    print "\$i = $i\n"
}'
$i = file1
$i = file2
$i = file3
[download]

If you want $i to contain the array index, you could use $#array which will give you the number of array elements minus one (the highest index) along with the range operator:

$ perl -we '
my @array = qw( file1 file2 file3 );
foreach my $i ( 0 .. $#array ) {
    print "\$i = $i\n"
}'
$i = 0
$i = 1
$i = 2
[download]

Also, if you want to index into an array you should do it like this: $array[0]. Not like you have it, @array[0]. The way you have written it, you are taking a slice.

This might get you a little bit closer to what you are trying to do...

Best,

Jim

You already are on the right path ( strict and warnigns are there ) but maybe you need to use some idioms more: firstly the use of the better form to open a file: lexical filehandle, checking if all was good: open my $h, '<', $file or die "cannot read from $file!"

Another common way, idiomatic way of Perl thinking is: uniqueness, quantity or existence of something lead immediately to use an hash. You read a list populating the hash with each item and later on you'll be able to check against this list as simply as:  .. if exists $files{$current_element}

But given your numbers (300 files is not a big deal nowadays..) you can also do all the work directly while reading the list file:

..
my $list_file = '/path/to/list.txt';

open my $read, '<', $list_file or die "cannot read from'$list_file'!";

while (<$read>){  # it populates $_ is the same of: defined $_ = <$rea
+d>
  chomp;
  my $ret = process ($_) if -e "./$_";
  if ($ret){print "$_ succesfully processed\n"}
  else{print "Warning: '$_' was not processed!\n"}
}

sub process{
 my $file = shift;
 open ... or return 0
 # read and do something
 close ..
 # implicitly return the last thing: if close succeded is 1 
}
[download]

L*

Hi Discipulus. I noticed you used a my declaration in a conditional statement. This is something I avoid since it can cause strange and subtle bugs. Refer to this node where Haukex pointed out to me the reason with this quote from perlsyn.

NOTE: The behaviour of a my, state, or our modified with a statement modifier conditional or loop construct (for example, my $x if ...) is undefined. The value of the my variable may be undef, any previously assigned value, or possibly anything else. Don't rely on it. Future versions of perl might do something different from the version of perl you try it out on. Here be dragons.