Hello flieckster,

You need to loop; for example:

use strict;
use warnings;
use POSIX qw( strftime );

my $dir  = $ARGV[0] // '.';
my $wait = $ARGV[1] //  10;

chdir $dir or die "$!";
my $count = () = glob '*';
print_dir_status($count);

if ($count > 0)
{
    my $equal = 0;

    until ($equal)
    {
        sleep $wait;
        my $new_count = () = glob '*';
        $equal = 1 if $new_count == $count;
        $count = $new_count;
        print_dir_status($count);
    }
}

sub print_dir_status
{
    my ($count) = @_;
    my  $time   = strftime "%a %d %b %Y %I:%M:%S %p", localtime;
    print "$time: there are $count files\n";
}
[download]

Update: Note that (contrary to the node title) it’s not necessary to store the results of the glob in an array. The syntax $count = () = glob '*'; evaluates glob in list context (via the assignment to empty parentheses), then implicitly puts that list into scalar context (by assigning to a scalar variable) to get the list count.

Hope that helps,

thats works perfectly! thank you so uch.

I'd like to check a directory for files, then wait for a period of time, then check the directory again and compare the first count to the second count.

That sounds like you want to use dnotify or the newer inotify, or some very similar notification mechanism if you are not using Linux (kqueue on the *BSDs, FSEvents on MacOS X). This avoids inefficient polling in userspace, the kernel will wake up your program whenever something changed that you wanted to be notified of (e.g. create or remove files).

Alexander

Please edit your question and add a problem statement; ie. what the current behaviour (result) is, and what the desired behavour would be. Essentially, what is your code doing or not doing that you feel it should/shouldn't be.