#!/usr/bin/perl

# http://perlmonks.org/?node_id=1197250
# Conway's life eyepopslikeamosquito

use strict;
use warnings;
use Time::HiRes 'time';

my $w = qx(tput cols) + 0; # probably linux only :)
my $h = qx(tput lines) - 7; # strange offset because of my REPL
# override for comparison with node results
$w = int sqrt 3e6;
$h = int 1 + 3e6 / $w;

my $board = '0' x $w x $h;
my $mask = '0' x $w . ('0' . "\xff" x ($w - 2) . '0') x ($h - 2) . '0' x $w;

# build starting state

sub place
  {
  my ($x, $y, $pattern) = @_;
  my $offset = $y * $w + $x;
  for ( $pattern =~ /.+/g )
    {
    substr $board, $offset, length $_, $_;
    $offset += $w;
    }
  }

place( 4, 4, <<END =~ tr/-O/01/r ); # glider gun
------------------------O-----------
----------------------O-O-----------
------------OO------OO------------OO
-----------O---O----OO------------OO
OO--------O-----O---OO--------------
OO--------O---O-OO----O-O-----------
----------O-----O-------O-----------
-----------O---O--------------------
------------OO----------------------
END

place( $w >> 1, $h >> 1, <<END =~ tr/-O/01/r ); # switch engine
----------
-------O--
-----O-OO-
-----O-O--
-----O----
---O------
-O-O------
----------
END

my $generations = 0;
my @offsets = ( 1, 2, $w, $w + 2, $w * 2, $w * 2 + 1, $w * 2 + 2 );
my $pad = '0' x ($w + 1);

#print "\e[H\e[J"; # clear screen
#print "\e[H", $board =~ tr/01/ O/r, "-" x $w, "$generations\n";

my $starttime = time;

for (1..2) # loop over generations
  {
  $generations++;

  my $all = $pad . $board . $pad;

  my $sum = $all =~ tr/1/2/r;                                # first offset
  ( $sum |= substr $all, $_ ) =~ tr/1357/2468/ for @offsets; # other 7

  $board |= $mask & $sum;      # prevent overflow at edges
  $board =~ tr/1-9/000011100/; # determine alive or dead

  #print "\e[H", $board =~ tr/01/ O/r, "-" x $w, "$generations\n";
  }

my $time = time - $starttime;
printf "\nw %d h %d cells %d time %.2f generations %d gen/sec %d" .
  " nanoseconds/cell/gen %d\n",
  $w, $h, $w * $h, $time, $generations, $generations / $time,
  $time / ($w * $h) / $generations *1e9;