package Organism;

use strict;
use warnings;

sub count {
   my $self = shift;
   return scalar keys %{ $self->{Cells} };
}

sub is_alive {
   my $self = shift;
   return 0 + exists $self->{Cells}->{ join ':', @_ };
}

# Input a list of [ x, y ] coords
sub insert_cells {
   my $self = shift;
   for my $r (@_) { $self->{Cells}->{ join ':', @{$r} } = undef }
}

# Return sorted list of cells in the Organism.
# Used for verification and testing the state of the organism.
sub get_live_cells {
   my $self = shift;
   sort { $a->[0] <=> $b->[0] || $a->[1] <=> $b->[1] }
      map { [ split /:/, $_ ] }
      keys %{ $self->{Cells} };
}

# Return the list of dead cells surrounding a cell
sub get_dead_cells {
   my ( $self, $x, $y ) = @_;
   ( (join ':', $x - 1, $y - 1) x !$self->is_alive($x - 1, $y - 1),
     (join ':', $x - 1, $y    ) x !$self->is_alive($x - 1, $y    ),
     (join ':', $x - 1, $y + 1) x !$self->is_alive($x - 1, $y + 1),
     (join ':', $x    , $y - 1) x !$self->is_alive($x    , $y - 1),
     (join ':', $x    , $y + 1) x !$self->is_alive($x    , $y + 1),
     (join ':', $x + 1, $y - 1) x !$self->is_alive($x + 1, $y - 1),
     (join ':', $x + 1, $y    ) x !$self->is_alive($x + 1, $y    ),
     (join ':', $x + 1, $y + 1) x !$self->is_alive($x + 1, $y + 1) );
}

sub get_num_live {
   my ( $self, $x, $y ) = @_;
     $self->is_alive( $x - 1, $y - 1 )
   + $self->is_alive( $x - 1, $y     )
   + $self->is_alive( $x - 1, $y + 1 )
   + $self->is_alive( $x    , $y - 1 )
   + $self->is_alive( $x    , $y + 1 )
   + $self->is_alive( $x + 1, $y - 1 )
   + $self->is_alive( $x + 1, $y     )
   + $self->is_alive( $x + 1, $y + 1 );
}

sub tick {
   my $self = shift;
   my %new_cells;
   for my $c (keys %{ $self->{Cells} }) {
      # Get the (up to 8) dead cells surrounding the cell
      my @zcells = $self->get_dead_cells( split /:/, $c );

      # Check the live cell
      # Note: next line equivalent to nlive == 2 || nlive == 3
      @zcells == 5 || @zcells == 6 and $new_cells{$c} = undef;

      # Check the dead cells
      for my $z (@zcells) {
         $self->get_num_live( split /:/, $z ) == 3 and $new_cells{$z} = undef;
      }
   }
   $self->{Cells} = \%new_cells;
}

sub new {
   my $class = shift;
   my %init_self = ( Cells => {} );
   bless \%init_self, $class;
}

1;