G'day hexcoder,

Perhaps, instead of a table of just templates, you could use a table of coderefs whose functionality includes preprocessing, unpacking, formatting, and anything else you need.

Here's a highly contrived and primitive example just to show the technique.

#!/usr/bin/env perl -l

use strict;
use warnings;

my %decode_type = (
    A => sub { "Do TypeA stuff with '$_[0]'" },
    B => sub { "Do TypeB stuff with '$_[0]'" },
);

while (<DATA>) {
    chomp;
    my ($type, $msg) = split /\s+/, $_, 2;
    my $decoded = $decode_type{$type}->($msg);
    print $decoded;
}

__DATA__
B message B1
A more complex message A1
B message B2
[download]

Output:

Do TypeB stuff with 'message B1'
Do TypeA stuff with 'more complex message A1'
Do TypeB stuff with 'message B2'
[download]

I don't know how useful that might be; however, your general description suggested this approach.

The idea/goal was to seperate the decoding engine (code) from the data structure descriptions (templates) in order to
• decrease (inter)dependencies
• reduce code by avoiding (slightly different) duplicates for different structures
So, I see your approach as the next best method, when I fail to express the structures with templates in a table. Using a table with handler functions is certainly the most flexible way allowing for very special decoding tasks.
Thanks, hexcoder

I'm glad to see that had, at least some, appeal.

It was, as stated, somewhat "primitive". Expanding upon that a little, the following is more generally what I had in mind, which removes duplicate code and separates the "decoding engine (code)" (putting it into Decoupled.pm).

The expanded script (note there's no change to the original while loop or input data):

#!/usr/bin/env perl -l

use strict;
use warnings;
use lib '.'; 

use Decoupled qw{
    preprocess_complex_message
    handle_generic_message
};

my %decode_type = (
    A => sub { 
        handle_generic_message(
            A => preprocess_complex_message($_[0])
        )
    },
    B => sub { 
        handle_generic_message(B => $_[0])
    },
);

while (<DATA>) {
    chomp;
    my ($type, $msg) = split /\s+/, $_, 2;
    my $decoded = $decode_type{$type}->($msg);
    print $decoded;
}

__DATA__
B message B1
A more complex message A1
B message B2
[download]

The Decoupled module:

package Decoupled;

use strict;
use warnings;

use Exporter 'import';
our @EXPORT_OK = qw{
    preprocess_complex_message
    handle_generic_message
};

sub preprocess_complex_message { 
    $_[0] =~ /more complex (.*)/; $1
}

sub handle_generic_message {
    sprintf "Do Type%s stuff with '%s'", @_
}

1;
[download]

The new output:

Do TypeB stuff with 'message B1'
Do TypeA stuff with 'message A1'
Do TypeB stuff with 'message B2'
[download]

— Ken