See glob.

for (glob "$var1/$var2/$var3/*.ksh") {
    print "$_\n";
}
[download]

For portability, it is better to use File::Spec:

use File::Spec;
...
my $pat = File::Spec->catfile($var1,$var2,$var3,'*.ksh');
for(glob $pat) {
    print "$_\n";
}
[download]

When I see the use of glob I often feel compelled to point out that it has its caveats, such as how it handles whitespace in its argument, and also that it does not list filenames beginning with a dot by default (which might be surprising to users when compared to readdir or File::Find). A thorough read of glob and File::Glob, which implements the former, is recommended.

Update: While File::Spec is often very good advice, I looked into this a bit, and note that the File::Glob doc discusses how on Win32, backslashes can interfere with escaping, and that forward slashes are recommended.

* wouldn't do what you want in single quotes either. glob will give you the list of files that match your pattern: my @files = glob "$var1/$var2/$var3/*.ksh"

Edit: I forgot the call to glob in my example :D, thanks haukex!

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use Path::Tiny;

my $var1 = '/home/choroba';
my $var2 = 'perl5';

say for path($var1, $var2)->children(qr/\.ksh$/);
[download]

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]

Hello dk27,

What about some alternatives? Such as File::Find

#!/usr/bin/env perl

use warnings;
use strict;
use File::Find;

my $location="$var1/$var2/$var3/";

sub find_ksh {
    my $F = $File::Find::name;

    if ($F =~ /ksh$/ ) {
        print "$F\n";
    }
}


find({ wanted => \&find_ksh, no_chdir=>1}, $location);
[download]

Or readdir:

opendir(my $dh, $some_dir) || die "Can't opendir $some_dir: $!";
my @files= map{s/\.[^.]+$//;$_}grep {/\.ksh$/} readdir DIR;
closedir $dh;
[download]

Both solutions are untested but they should work straight out of the box.

Update: Also if you are running linuxOS or Cygwin terminal:

Update3: as monk haukex pointed out using back ticks is not a good option, read the link on his response bellow why.

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

my $path = shift || '.';

my @files = `find $path -name '*.ksh' -o -name '*.txt'`;

chomp @files;
print Dumper \@files;
[download]

WindowsOS with Cygwin:

my @files = `find $path \( -name '*.ksh' -o -name '*.txt' \)`;
[download]

Update2: Similar question with some maybe useful answers combining regex on search see (Re: File::Find find several strings in one directory).

Hope this helps.

It's important to note there is a difference between readdir/glob and File::Find/find: the latter recurses into subdirectories as well. As for running external commands, I wrote about that, including the potential security risks, at length here. At the very least I would recommend using something like IPC::System::Simple's capturex, e.g. my @files = capturex("find",$path,qw/ ( -name *.ksh -o -name *.txt ) /);

"... the latter recurses..."

But fortunately there is -maxdepth 0. From find:

-maxdepth n
             Always true; descend at most n directory levels below the
+ command line arguments.  If any
             -maxdepth primary is specified, it applies to the entire 
+expression even if it would not
             normally be evaluated.  ``-maxdepth 0'' limits the whole 
+search to the command line argu-
             ments.
[download]

Best regards, Karl

«The Crux of the Biscuit is the Apostrophe»

Furthermore I consider that Donald Trump must be impeached as soon as possible

Of course, this will fall apart a bit when fed "$var7/$var8/test*.dat".

Imagine their surprise, getting back a list of *.kshfiles from that input. :-)

Here's another way to do it, using Path::Class, which can also do the copying for you:

use Path::Class qw/file dir/;

for my $file ( dir($var1,$var2,$var3)->children ) {
    next if $file->is_dir
         || $file->basename !~ /.+\.ksh$/;
    $file->copy_to($target)
        or die "Failed to copy $file to $target";
}
[download]

Note this will copy filenames beginning with a dot as well.