Wasn't sure if this belongs here, or in Obfuscations.

Having once run:

use strict;
use warnings;
use Storable;

my (%table);
foreach my $i (0..9) {
  foreach my $j ($i..9) {
    $table{$i}{$j} = $table{$j}{$i} = $i + $j
  }
}

store \%table, 'addition_table';
[download]

I present to you: addition!

use strict;
use warnings;
use Storable;

my %table = %{retrieve('addition_table')};
my @problem = @ARGV;
my (%matrix);
foreach my $number (@problem) {
  my $log = 0;
  push @{$matrix{$log++}}, $_ for reverse (split //, $number);
}

my $col = 0;
while (exists $matrix{$col}) {
  my @column = @{$matrix{$col}};
  my $first = shift @column;
  while(scalar @column > 0) {
    my $second = shift @column;
    $first = $table{$first}{$second};
    if (length($first) > 1) {
      $first = substr($first,-1,1);
      push @{$matrix{$col + 1}}, 1;
    }
  }
  $matrix{$col++} = $first;
}  
printf "%s",$matrix{$col - $_} for (1..$col);
print "\n";
[download]

H:\perl>perl adder.pl 1
1

H:\perl>perl adder.pl 21 14 99 6 12
152

H:\perl>perl adder.pl 999999999999999999999999999999999999999999 1
1000000000000000000000000000000000000000000
[download]

Addition tables for other number systems are left as an exercise for the (extremely bored) reader. Vaguely apropos of Multiply Hex values. I started to write a program to do multiplication and realized I needed to figure out how to add first.