Sure, here you go:

use strict; use warnings;
use Algorithm::Diff qw/ LCS_length /;

( my $name = $ARGV[0] ) && length $ARGV[0] > 2 or die "Usage: `$0 <nam
+e>` (min. 3 letters)";

open my $fh, '<', '/usr/share/dict/words' or die $!;

my $found = 0;
while ( <$fh> ) {
    next unless LCS_length( [ split //, $name ], [ split // ] ) == len
+gth $name;
    $found++;
    print "$found $_";
}

__END__
[download]

• How to load a clever module and import its LCS_length function to do all the work :-)
• How to capture the user input from the command line in the array @ARGV
• How to open a file for reading
• How to create a counter and increment it in a loop
• How to read from an open filehandle line-by-line (which avoids reading it all into memory), using:

  while ( <$fh> ) {
      ...
  }
  [download]

• The most obfuscated thing in this script: How to be lazy and not have to tell a function what to operate on by using the default argument, which is the current value of the magic variable $_. So in a loop I can say:

  while ( <$fh> ) { # each line is loaded into $_ in turn
      my @characters = split //;
  }
  [download]

  , omitting the second argument to split, and Perl knows to Do The Right Thing. More self-documenting usage would be:

  while ( my $line = <$fh> ) { # each line now in $line
      my @characters = split //, $line;
  }
  [download]

Hope this helps! have fun ....

edit: fixed missing parens

You are too kind! I totally do see myself thinking of a project like this one and making it a reality when I am more proficient in Perl. Surprisingly I follow almost all of your code! The two things that cause some head scratching is loading the module and the second argument that needs to be passed. Is this just the length of the name? I know I have loaded modules previously, I just forgot how, I will do my research.

See Algorithm::Diff, especially the LSC_length function in http://search.cpan.org/~tyemq/Algorithm-Diff-1.1903/lib/Algorithm/Diff.pm#LCS_length.

The program looks for your name's letters as subsequences of the words in the word list. If the length of the found subsequence is equal to the length of your name, then it means that all letters of your name were found in the right order in the candidate word.

the second argument that needs to be passed. Is this just the length of the name?

No, there's only one argument expected. That line of code is the program's error checking. It does two things, but acts on the same variable both times.

( my $name = $ARGV[0] ) && length $ARGV[0] > 2 or die "Usage: `$0 <nam
+e>` (min. 3 letters)";
[download]

What's happening here is we are evaluating the truth of an expression without using an explicit if statement.

my $name = $ARGV[0]
[download]

will evaluate to false if the first argument passed in is empty (i.e. non-existent) because then the value of $name will be false (so `0` would fail also)[1]. If that happens, the or die ... kicks in. But if it evaluates to true, then

&& length $ARGV[0] > 2
[download]

is evaluated for truth, so at this point we know we have some kind of value in the arg passed in, and now we check that it's at least three characters long. If the second part of the evaluation fails, the whole thing fails (because of the &&), and again we go to or die ....

Finally, in our error message emitted upon dying, we use $0, the global variable that holds the name of the currently executing script, and explain what the problem was.

Amazing how much useful stuff you can do with one line of Perl, isn't it?

[1] So in Perl you can evaluate truth very concisely:

while ( 1 ) { # runs forever
    ...
}

if ( 0 ) { # won't run
    ...
}

sub foo {
    return 'something'; # or maybe not
}

if ( foo() ) { # only runs if foo() returns something
    ...
}
[download]

Hope this helps.

edit: added missing parens



The way forward always starts with a minimal test.

And you might very well be astonished by the small numbre of code lines needed to doing that.

I learned Linux and pearl

Command line one-liner:

perl -wMstrict -E 'print for grep /adam/, <>' /usr/share/dict/words
[download]

Script form (overly verbose so it's easier to understand):

use warnings;
use strict;

my $word_file = '/usr/share/dict/words';

open my $fh, '<', $word_file
  or die "can't open the $word_file file!: $!";

while (my $line = <$fh>){
    if ($line =~ /adam/){
        print $line;
    }
}
[download]

Hi Steve,

++ for the code, but I don't think that you program will produce a list anywhere near the one by 1nickt, since your code looks for the adam letters in sequence.

Yeah, I knew Nick would come back with some code as well, so I thought I'd put something out there that the OP could glean in the meantime ;)