FAQ! Take a look at perlfaq5. It references Number::Format, and also shows code for a regex and a subroutine, if you'd rather not use the module.

$number =~ s/(\d{1,3}?)(?=(\d{3})+$)/$1,/g;
[download]

The lookahead (?=(\d{3})+$) ensures that the number of digits before each underscore we insert is a multiple of 3.

An extra set of parentheses fools Perl because the regex parser barks when there are two quantifiers in a row, which is perfectly legitimate here.

This issue was also discussed in the thread Splitting every 3 digits?.

To do it without capturing and resubstituting, you can add a lookbehind:

s/(?<=\d)(?=(?:\d{3})+\b)/$sep/g;
[download]

This also works:

substr($n, pos($n), 0) = $sep while ($n =~ /\d(?=(?:\d{3})+\b)/g);
[download]

As does:

substr($n, -($_*3 + ($_-1)*length($sep)), 0) = $sep for (1..int((lengt
+h($n)-1)/3));
[download]

Originally posted as a Categorized Answer.

$number =~ s/(?<=\d)(?=(?:\d\d\d)+\b)/,/g;
[download]

for ( $number )
{
  /\./
    ? s/(?<=\d)(?=(\d{3})+(?:\.))/,/g
    : s/(?<=\d)(?=(\d{3})+(?!\d))/,/g;
}
[download]

This says if the number has a decimal point, end there for the purposes of commafication. Otherwise, go to the end of the string.

Here's a simple (and quite fast) one using substr:

my $number = 132452345;
for ( my $i = -3; $i > -1 * length($number); $i -= 4 )
{
    substr( $number, $i, 0 ) = ',';
}
[download]

For integers, one can avoid reverse as well as the repeated substr derivation of the remaining string in the loop:

sub commafy_int
{
    my $n = shift;
    length($n) > 3 or return $n;
    my $l = length($n) - 3;
    my $i = ($l - 1) % 3 + 1;
    my $x = substr($n,0,$i) . ',';
    while ( $i < $l )
    {
        $x .= substr($n,$i,3) . ',';
        $i += 3;
    }
    $x . substr($n,$i)
}
[download]

Camel 3 has this on page 657:

$# [XXX,ALL] Don't use this; use sprintf instead.

And on the previous page, "XXX" is defined as meaning:

Deprecated, do not use in anything new.

--
<http://www.dave.org.uk>

"The first rule of Perl club is you don't talk about Perl club."

In addition to the deprecatedness of $# mentioned by davorg, how would you go about using sprintf to put thousands separators into numbers? I don't see a simple way to do this - if there was it'd be mentioned in the perlfaq to this topic, I'd guess.

-- Hofmator

Your test script was very educational for me. I'd never seen use of the Benchmark module before. It looks like you've certainly gotten a fast method for adding in the thousands separators.

For those who need something a bit easier to follow, I'd like to add the following to this topic:

#!/usr/bin/perl
use Number::Format;
my $num = 12349329824342;
my $nf = new Number::Format(-thousands_sep => ',');  
my $separated_num = $nf->format_number($num);
[download]

$num = 123456789;
$num = reverse $num;     # reverse the number's digits
$num =~ s/(\d{3})/$1,/g; # insert comma every 3 digits, from beginning
$num = reverse $num;     # Reverse the result
$num =~ s/^\,//;         # remove leading comma, if any
[download]

For other more indepth formatting, there's always Number::Format

my $number = '$12345678.90'; # dollars
$_ = reverse $number;
s/(\d{3})(?=\d)(?!\d*\.)/$1,/g;
$number = reverse $_;
[download]

sub puntato {
    my $n=reverse($_[0]);
    my $x='';
    while(length($n)>3) {
        $x=$x.substr($n,0,3).'.';
        $n=substr($n,3);
    }
    $x=reverse($x.$n);
    return($x);
}
[download]

How about this?

sub puntato{ my $z=reverse $_[0];$z=~s/(\d{3})(?=\d)/$1\./g;scalar(rev
+erse($z))}
[download]

Boris

$number = 123456789;
$number = reverse join ",", (reverse $number) =~ /(\d{1,3})/g;
[download]