http://qs321.pair.com?node_id=1171121


in reply to Got some problem with read write file

m/\d \t (\w+) \t \.+/g

[download]

Your input doesn't seem to contain a space between the first digit and the tab following it, similarly, there's no space after the tab, etc. Maybe you wanted to use the /x modifier, too, which ignores unescaped space?

That still would'n work, though, as \.+ means "at least one dot", but there's no dot after the tab. Maybe you wanted to use .+ , which will make the regex work - but it's useless, you don't need it at all. Also, there's no point to use the /g modifier, as you only match once (there's an if , not a while ), so just say 

    if ($line =~ /\d \t (\w+) \t/x) {

[download]
($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,

[download]

Replies are listed 'Best First'.
Re^2: Got some problem with read write file
by SilverWol (Novice) on Sep 03, 2016 at 20:53 UTC
    Thank you choroba for your precise answer, I changed my code to this: 
    #!usr\bin\perl -w
open HUBFILE,"1048_undefined.tsv";
@hub=();
while(my $line = <HUBFILE>){
         while ($line =~ /\d \t (\w+) \t/x) {
        push(@hub,$1);
            }
            }close HUBFILE;
            $L=@hub;
    open OUT,">hubs.txt";
    for($i=0;$i<$L;$i++){
    print OUT "HUB:$hub[$i]\n";
    }
    close OUT;

    [download]
    and i guess something is wrong with the second "while"
[reply]
[d/l]
      Why is the second while there? Do you want to find several occurences on the same line? Also, you probably don't want to print all the genes found so far after finding a gene, you want to print them once all of them have been found: 
      #!/usr/bin/perl
use warnings;
use strict;

open my $HUBFILE, '<', '1048_undefined.tsv' or die $!;
my @hubs;
while (my $line = <$HUBFILE>) {
    push @hubs, $1 if $line =~ /\d \t (\w+) \t/x;
}
close $HUBFILE;

open my $OUT, '>', 'hubs.txt' or die $!;
for my $hub (@hubs) {
    print {$OUT} "HUB:$hub\n";
}
close $OUT;

      [download]

      Notice I modified some other parts of the code, too: I switched to 3-argument open with lexical filehandles, foreach style loop instead of the C-style one, etc.

      ($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,

      [download]
[reply]
[d/l]
[select]

        Thought wrong about the second while, I want to print in the second file a list with all the gene names but it just print only the 1st gene name. I didn't know about the lexical filehandles, thank you!

[reply]

In Section Seekers of Perl Wisdom