Where in your code are you checking for whether the variable is locked or not? The locking is "advisory", that means you need to manually check for whether a variable is locked or not. See threads::shared. You need to call lock wherever you want to modify $LockVar:

    async { lock $LockVar; $LockVar = 'Haha'; sleep 3; print "Thread 1
+: $LockVar\n" };
    async { lock $LockVar; $LockVar = 'Hehe'; sleep 3; print "Thread 2
+: $LockVar\n" };
[download]

Personally, I try to stay away from approaches that require locks. Usually, a queue into which I can put new values and a single thread that reads from that queue and updates the master data at opportune times is sufficient. Or simply using a relational database as backend, as that takes care of the consistency for me. But if you're using threads, you most likely did so in the hope of gaining performance with short-lived calculations, which talking to a database usually precludes.

Update: Here is how the locking could work in a self-contained example:

#!perl -w
use strict;
use 5.010;
use threads;
use threads::shared;

my $LockVar :shared;
$LockVar = 'default';

async { lock $LockVar; my $oldLockVar= $LockVar; $LockVar = 'Haha'; sl
+eep 3; say "Thread 1: set var from $oldLockVar to $LockVar" };
async { lock $LockVar; my $oldLockVar= $LockVar; $LockVar = 'Hehe'; sl
+eep 5; say "Thread 2: set var from $oldLockVar to $LockVar" };

my $TryToReadLockVar = threads->new(
    {'void' => 'void'},
    sub {
        my $count = 1;
        while( 1 ) {
            say "try to modify the Lock var {$count} time";
            $count += 1;
            lock($LockVar); # !!!
            say "Now setting LockVar";
            $LockVar = 'this lock var has been change';
            last;
        }
    },
);

$TryToReadLockVar->join();    
say "LockVar is now $LockVar";
__END__
try to modify the Lock var {1} time
Thread 1: set var from default to Haha
Thread 2: set var from Haha to Hehe
Now setting LockVar
LockVar is now this lock var has been change
Perl exited with active threads:
        0 running and unjoined
        2 finished and unjoined
        0 running and detached
[download]