Perl 6 grammars - setting the actions object

Anonymous Monk has asked for the wisdom of the Perl Monks concerning the following question:

Hello dear monks,

I am trying to work my way through Perl grammars and, more specifically, actions objects.

I have written this grammar for a subset of JSON (as a shorter example of my larger problem):

grammar My-Grammar {
    token TOP       { \s* <object> \s* }
    rule object     { '{' \s* <pairlist> '}' \s* }
    rule pairlist   {  <pair> * % \,  }
    rule pair       {  <string>':' <value> }
    token string    {  \" <[ \w \s \- ' ]>+ \"  }
    token number    { [ \d+ [ \. \d+ ]? ] | [ \. \d+ ] }
    token value     {   <object> | <string> | <number> 
               | true    | false     | null 
    }
}
[download]

Used with the following JSON subset string and parsing call:

my $source-string = q/{
  "firstName": "John",
  "lastName": "Smith",
  "isAlive": true,
  "age": 25,
  "address": {
    "streetAddress": "21 2nd Street",
    "city": "New York",
    "state": "NY",
    "postalCode": "10021-3100"
  },
  "spouse": null
}/;
my $match = My-Grammar.parse($source-string);
say ~$match if $match;
# say $match.made if $match;
[download]

I get the following stringified match object:

{
  "firstName": "John",
  "lastName": "Smith",
  "isAlive": true,
  "age": 25,
  "address": {
    "streetAddress": "21 2nd Street",
    "city": "New York",
    "state": "NY",
    "postalCode": "10021-3100"
  },
  "spouse": null
}
[download]

So parsing the string with the grammar seems to work correctly.

I have a problem when I try to add an actions object.

This is about the best actions class I could come up with so far:

class My-actions {
    method TOP($/) {
        make $/.values.[0].made;
    };
    method object ($/) {
        make $<pairlist>.made.hash.item;
    }
    method pairlist($/) {
        make $<pair>>>.made.flat;
    }
    method pair($/) {
        make $<string>.made => $<value>.made ;
    }
    method string($/) { make ~$/; }
    method number($/) { make +$/.Str; }
    method value($/) { 
        given ~$/ {
            when "true"  {make Bool::True;}
            when "false" {make Bool::False;}
            when "null"  {make Any;}
            default { make ~$/;}
        }  
    }
}
[download]

With this actions class, I get the following AST:

{"address" => {
    "streetAddress": "21 2nd Street",
    "city": "New York",
    "state": "NY",
    "postalCode": "10021-3100"
  }, "age" => 25, "firstName" => "John", "isAlive" => True, "lastName"
+ => "Smith", "spouse" => (Any)}
[download]

Except for the address component, the AST seems correct.

The address component is not transformed into AST nodes obviously because of this line:

            default { make ~$/;}
[download]

in the value method of the actions class, which just stringifies the address sub-object. I have put that line so far as a temporary workaround just to get the overall shebang sort of working, but I have no idea how to get further. Specifically, I have tried many things, but I just can't figure out how to identify that the value is itself (recursively) an object and, even if I knew how to identify that, I still probably wouldn't know how to process it to produce a proper AST subtree for it.

Would a nice monk around here be kind enough to enlighten me on this last part?

Comment on Perl 6 grammars - setting the actions object Select or Download Code

Replies are listed 'Best First'.
Re: Perl 6 grammars - setting the actions object by duelafn (Parson) on Jul 19, 2016 at 01:37 UTC
One solution is to pass-through the made value instead of stringifying. There may be a better way of doing this (update: the post by moritz below is that better way), but this at least works: `token value { <val=object> \| <val=string> \| <val=number> \| true \| false \| null } # ... given ~$/ { when "true" {make Bool::True;} when "false" {make Bool::False;} when "null" {make Any;} default { make $<val>.made; } }` [download] Though it would probably be better to pass-through if `$<val>` is defined at all rather than rely on the stringified fall-through: `return make $<val>.made if $<val>; given ~$/ { when "true" {make Bool::True;} when "false" {make Bool::False;} when "null" {make Any;} default { die; } }` [download] Good Day, Dean	[reply] [d/l] [select]
Re^2: Perl 6 grammars - setting the actions object by Anonymous Monk on Jul 19, 2016 at 07:44 UTC
Thank you very much. I did not think at all about this solution, I'll try it as soon as possible. I definitely agree that stringifying the parts I couldn't handle better is not a good solution, I only did it as a cheap temporary debugging scaffolding so that the overall thing could succeed and that I could check that at least the rest was working properly.	[reply]
Re: Perl 6 grammars - setting the actions object by moritz (Cardinal) on Jul 21, 2016 at 21:30 UTC
The solution I used in JSON::Tiny is to have separate rules for the different literal values: `proto token value {*}; token value:sym<true> { <sym> }; token value:sym<false> { <sym> }; token value:sym<null> { <sym> }; ...` [download] And then in the action class, have one method per literal: `method value:sym<true>($/) { make Bool::True } method value:sym<false>($/) { make Bool::False } method value:sym<null>($/) { make Any }` [download] But the key is, as already mentioned by duelafn, to create the right object in the action directly, and not try to post-press the made value later on. Perl 6 - the future is here, just unevenly distributed	[reply] [d/l] [select]


Clear questions and runnable code get the best and fastest answer
	PerlMonks