http://qs321.pair.com?node_id=1166627


in reply to Re: Getting lines in a file between two patterns
in thread Getting lines in a file between two patterns

I made some experiment with these lines of codes and maybe I find an issue (I'm not a perl expert...). If input file is like below, with two START-END sections in succession, perl script seems to skip the "START" line after the previous "END" ones, and so it doesn't print the content of the paragraph. I can't say which can be the reason for this behaviour

__DATA__

XXXX
YYYY
START
These are the first
set of lines
which are to be extracted
END
START
New line
And new 
Will be extracted?
END
XXX
ZZZ
YYY
START
These are the second
set of lines
which are to be extracted
END
aasds
tteret
tertetr

[download]

Replies are listed 'Best First'.
Re^3: Getting lines in a file between two patterns
by hippo (Bishop) on Jun 27, 2016 at 08:28 UTC

    I am unable to reproduce your findings. Here are the results with perl 5.20.3:

    $ cat 980408.pl 
#!/usr/bin/perl -w
use strict;

while (<DATA>)
{
    process_record() if /^START/;
}

sub process_record
{
   my $line;
   while ($line = <DATA>, $line !~ /^END/)
   {
      print "$line"
   }
   print "\n";  #a printout spacer for next record
}

__DATA__

XXXX
YYYY
START
These are the first
set of lines
which are to be extracted
END
START
New line
And new 
Will be extracted?
END
XXX
ZZZ
YYY
START
These are the second
set of lines
which are to be extracted
END
aasds
tteret
tertetr
$ ./980408.pl 
These are the first
set of lines
which are to be extracted

New line
And new 
Will be extracted?

These are the second
set of lines
which are to be extracted

$

    [download]
[reply]
[d/l]
Re^3: Getting lines in a file between two patterns
by Marshall (Canon) on Jun 27, 2016 at 15:29 UTC
    In order to reproduce your symptoms, if one of the START tokens doesn't start in column 1 (right at the beginning of the line), then then it wouldn't be recognized and that record would be skipped.

    I made some slight changes to allow for START and END not being at the beginning of the line. Also, I eliminated the use of the "comma operator" in the sub's while statement in favor of an "and" statement. This should handle the case of a malformed record missing an "END" at the end of the DATA a bit better.

    Your DATA as posted does indeed work as hippo demonstrates. This code should work on any Perl >= 5.6 - nothing "fancy" about it.

    This is a very exacting business and when making a bug report, please post exactly the DATA that causes the problem, verbatim. 

    #!/usr/bin/perl -w
use strict;

while (<DATA>)
{
    process_record() if /^\s*START/;
}

sub process_record
{
   my $line;
   while (defined ($line = <DATA>) and $line !~ /^\s*END/)
   {
      print "$line"
   }
   print "\n";  #a printout spacer for next record
}

__DATA__

XXXX
YYYY
START
These are the first
set of lines
which are to be extracted
END
   START
New line
And new 
Will be extracted?
END
XXX
ZZZ
YYY
START
These are the second
set of lines
which are to be extracted
END
aasds
tteret
tertetr

    [download]
    As a comment, this malformed "START" record problem applies to all of the code in this thread. This is not unique to my code. "  START" vs "START" is my best guess as what you did wrong in your DATA.
[reply]
[d/l]
[select]
      Adapt my code like this: 
      #!/usr/bin/perl
use warnings;
use strict;

my @current_record;

while (<DATA>)
{
    process_record() if /^\s*START/;
}

foreach (@current_record)
{
    print;
}

sub process_record
{
   my $line;
   @current_record=();
   
   while (defined ($line = <DATA>) and $line !~ /^\s*END/)
   {
      push @current_record, $line;
      
   }
}


__DATA__
XXXX
YYYY
START
These are the first
set of lines
which are to be extracted
END
START
These are the second
set of lines
which are to be extracted
END
XXX
ZZZ
YYY
START
These are the third
set of lines
which are to be extracted
END
aasds
tteret
tertetr

      [download]
[reply]
[d/l]

      Hi,

      How can I get only the last set of pattern matched lines.

      INPUT __DATA__:

      XXXX
YYYY
START
These are the first
set of lines
which are to be extracted
END
START
These are the second
set of lines
which are to be extracted
END
XXX
ZZZ
YYY
START
These are the third
set of lines
which are to be extracted
END
aasds
tteret
tertetr

      [download]

      OUTPUT:

      These are the third
set of lines
which are to be extracted

      [download]

      Thanks,

      Gopi

      2018-04-23 Athanasius added code and paragraph tags

[reply]
[d/l]
[select]

        Push lines to an array, clear it at each START.

        #!/usr/bin/perl
use strict;
my $flag  = 0;
my @lines = ();
while (<DATA>){
  if (/^\s*END/){
    $flag = 0
  } elsif (/^\s*START/){
    $flag = 1;
    @lines = ();
  } elsif ($flag) {
    push @lines,$_;
  }
}

print join '',@lines;

        [download]
        poj
[reply]
[d/l]

In Section Seekers of Perl Wisdom