extracting elements by key from an array of hashes

ciderpunx has asked for the wisdom of the Perl Monks concerning the following question:

I have an AoH that looks like this:

my @aoh = ( 
    {k0 => 'v0' }
  , {k1 => 'v1' }
  , {k2 => 'v2' }
  , {k3 => 'v3' }
);
[download]

I want to pull out the value of the element with key k2. The nicest way I can think of to do this is something like

$val = [grep {(keys $_)[0] eq 'k2'} @aoh]->[0]{'k2'};
[download]

But that's kind of disgusting. Is there a nicer way?

Update: Corion pointed out that I could just convert the AoH into a hash given the keys are unique and have a single value each. Like:

my %h = map {%$_} @aoh;

## now its just:
say $h{'k2'};
[download]

--
Charlie Harvey.

Comment on extracting elements by key from an array of hashes Select or Download Code

Replies are listed 'Best First'.

Re: extracting elements by key from an array of hashes
by choroba (Cardinal) on Sep 25, 2015 at 09:58 UTC

my %hash = ( k0 => 'c0',
             k1 => 'v1',
             k2 => 'v2',
             k3 => 'v3',
           );
my $search = 'k2';
my $val = $hash{$search};
[download]

Even if the keys aren't unique, you might want to store the data in a HoA instead:

my %hash = ( k0 => ['c0'],
             k1 => ['v1'],
             k2 => ['v2', 'v42'],
             k3 => ['v3'],
           );
my $search = 'k2';
my @vals = @{ $hash{$search} };
[download]

لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ

[reply]
[d/l]
[select]

Re^2: extracting elements by key from an array of hashes

by ciderpunx (Vicar) on Sep 25, 2015 at 10:06 UTC

--
Charlie Harvey.

[reply]

Re^3: extracting elements by key from an array of hashes

by choroba (Cardinal) on Sep 25, 2015 at 10:35 UTC

my %hash = map %$_, @rpc;
[download]

لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ

[reply]
[d/l]

Re^3: extracting elements by key from an array of hashes

by davido (Cardinal) on Sep 25, 2015 at 14:57 UTC

Keep in mind that you have no obligation to store data internally in inconvenient formats. If it is more convenient to manipulate it internally as a hash, do that conversion at the earliest possible point after reading it in, and convert back at the latest possible point if you ever have to output the structure again.

Dave

[reply]

Re^3: extracting elements by key from an array of hashes

by Anonymous Monk on Sep 25, 2015 at 10:45 UTC

... and if there is potentially more than one value per bucket, simply make each element an arrayref. Auto-vivification makes this trivially easy to do.

[reply]

Re: extracting elements by key from an array of hashes
by Discipulus (Canon) on Sep 25, 2015 at 10:37 UTC

grep defined, map {$_->{'k2'}} @aoh;
[download]

There are no rules, there are no thumbs..
Reinvent the wheel, then learn The Wheel; may be one day you reinvent one of THE WHEELS.

[reply]
[d/l]

Re^2: extracting elements by key from an array of hashes

by Athanasius (Archbishop) on Sep 25, 2015 at 13:25 UTC

Hello Discipulus,

grep defined, map {$_->{'k2'}} @aoh;

This works well as long as the hash value is itself defined. But if the hash entry exists with a value of undef:

my @aoh =
(
    { k0 => 'v0'  },
    { k1 => 'v1'  },
    { k2 => undef },
    { k3 => 'v3'  },
);
[download]

then the result of the grep will be indistinguishable from the case in which the hash entry does not exist at all. The following does distinguish between these two cases:

map { exists $_->{k2} ? $_->{k2} : () } @aoh;
[download]

Hope that helps,

Athanasius <°(((>< contra mundum Iustus alius egestas vitae, eros Piratica,

[reply]
[d/l]
[select]

Re^3: extracting elements by key from an array of hashes

by mr_ron (Chaplain) on Sep 26, 2015 at 00:52 UTC

my @aoh = ( 
    {k0 => 'v0' }
  , {k1 => 'v1' }
  , {k2 => 'v2' }
  , {k3 => 'v3' }
);

my ($val) = grep {exists $_->{k2}} @aoh;
$val &&= $val->{k2};
[download]

[reply]
[d/l]

Re^3: extracting elements by key from an array of hashes

by Discipulus (Canon) on Sep 25, 2015 at 19:24 UTC

There are no rules, there are no thumbs..
Reinvent the wheel, then learn The Wheel; may be one day you reinvent one of THE WHEELS.

[reply]
[d/l]


Think about Loose Coupling
	PerlMonks