Re: Splitting a string on commas except when inside quotes

Trivial solution using Text::CSV_XS (which is what I would reach for first):

#!/usr/bin/env perl

use strict;
use warnings;
use Text::CSV_XS;

my $csv = Text::CSV_XS->new;

my $line =
  '11/21/2022,Payment,"Transfer to Smith, account 2",,USD,,123.60,';
print "  $line\n";

$csv->parse ($line);
my ( $fDate, $fType, $fDetails, $fRef, $fCurrency,
  $fAmount, $fPaidOut, $fFees )
      = $csv->fields;

printf("\n  Date: %s;  Type: %s;  \n"
  ."  Details: %s\n  Reference: %s\n"
  ."  Currency: %s;  Amount: %s;  PaidOut: %s; Fees: %s;\n",
  $fDate, $fType, $fDetails,
  $fRef, $fCurrency, $fAmount, $fPaidOut, $fFees );
[download]

Enjoy.

🦛

Comment on Re: Splitting a string on commas except when inside quotes Download Code

Replies are listed 'Best First'.

Re^2: Splitting a string on commas except when inside quotes
by Tux (Canon) on Jan 02, 2023 at 17:11 UTC

Though that is a perfect answer, the code you showed uses parse and thus is unsafe to use when upgrading from this easy single-line example to parsing a complete file record by record, wher getline whould be the preferred method to use.

Below is an example that uses more recent Text::CSV_XS' csv function

#!/usr/bin/perl

use 5.014001;
use warnings;
use Text::CSV_XS qw( csv );

my $line =
  '11/21/2022,Payment,"Transfer to Smith, account 2",,USD,,123.60,';
say "IN: $line";

my $aoa = csv (in => \$line);

my ($fDate, $fType, $fDetails, $fRef, $fCurrency, $fAmount, $fPaidOut,
    $fFees) = @{$aoa->[0]};

printf "\n  Date: %s;  Type: %s;  \n".
       "  Details: %s\n  Reference: %s\n".
       "  Currency: %s;  Amount: %s;  PaidOut: %s; Fees: %s;\n",
    $fDate, $fType, $fDetails,
    $fRef, $fCurrency, $fAmount, $fPaidOut, $fFees;
[download]

to upgrade from this single line to the complete file

my $aoa = csv (in => \$line);
[download]

changes to

my $aoa = csv (in => $file);
[download]

And then all is available in the $aoa

foreach my $record (@$aoa) {
    my ($date, $type, $dtls, $ref, $curr, $amt, $paid, $fees) = @$reco
+rd;
    ...;
    }
[download]

Enjoy, Have FUN! H.Merijn

[reply]
[d/l]
[select]


good chemistry is complicated, and a little bit messy -LW
	PerlMonks