Don't call sleep from within your Tk application. Doing anything blocking like that will make the whole application unresponsive and not handle any events, and when you wake up from the sleep, all unhandled events will be handled again.

If you want to sleep look at a Tk->after like in this demo.

If you want to run a long running process that actually does some work, do that in a thread or outside of your UI program, or split it up into small chunks so that you can return to the Tk mainloop in between.

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11148771
use warnings;
use Tk;

my $mw = MainWindow->new;

my %btns;
for (qw(alpha beta gamma)){
    my $name = $_;
    $btns{$_} = $mw->Button(
        -text => $_,
        -command => sub{foo($name)},
        )->pack;
}

MainLoop;

sub foo{

    my $name = shift;
    for (keys %btns){
        $btns{$_}->configure(-state => 'disabled');
    }

    my %dispatch =(
        alpha => \&alpha,
        beta => \&beta,
        gamma => \&gamma,
        );

    $dispatch{$name}->($name);
}

sub normal {
  for (keys %btns){
      $btns{$_}->configure(-state => 'normal');
  }
}

sub alpha{
    print "alpha\n";
#    sleep 4;
    $mw->after( 4_000 => \&normal );
}
sub beta{
    print "beta\n";
#    sleep 4;
    $mw->after( 4_000 => \&normal );
}
sub gamma{
    print "gamma\n";
#    sleep 4;
    $mw->after( 4_000 => \&normal );
}
[download]

Thank you all, that's just what I was looking for. And now I also have a better understanding of the event loop.