while (<FILE>) {
    my $var = scalar $_;
    $response->body($var);
    return $response->finalize;
}
[download]

$_ is already a scalar. Calling it in a scalar context doesn't change anything, so you can also use

my $var = $_;
[download]

If you return from a while loop, the loop is done. In fact, the whole subroutine is done. The next iteration never happens.

autoflush is documented in IO::Handle:

Any unread data in the buffer will be discarded

Are you sure you want to do that?

Update: You used flush on the input, not output. But perlvar for $| which is the same as autoflush says:

This has no effect on input buffering

See the section Delayed Response and Streaming Body in the PSGI specification.

What you want is something like this (untested):

use strict;
use warnings;
####use Plack::Response; # doesn't seem to support streaming response

use Path::Tiny;
use File::MimeInfo;

sub return_psgi {
    my $self = shift;
    my $path_file = shift;

    my $content_type = mimetype($path_file);
    $content_type = 'application/octet-stream' if not defined $content
+_type;
    
    my $content = path($path_file);
    my $content_download = $content->slurp;

    require File::Spec::Unix;
    my $basename = $path_file;
    $basename =~ s|\\|/|g;
    $basename = ( File::Spec::Unix->splitpath($basename) )[2];
    $basename =~ s|[^\w\.-]+|_|g;

    return sub {
       my $responder = shift;
        my $writer = $responder->(
            [ 200, [
                   'Content-Type' => $content_type,
                   'Content-Disposition' => qq[attachment; filename="$
+basename"],
               ]
            ]
        );

        open (FILE, "< $path_file") or die "can't open $path_file: $!"
+;
        binmode FILE;
        local $/ = \102400;
        while (<FILE>) {
            $writer->write($_);
        }
        $writer->close();
        close FILE;
    }
}
[download]

much easier than that

  
$res->body($io);
Or

use Path::Tiny qw/ path /;
    return [
        200,
        [
            'Content-Type' => 'text/plain; charset=UTF-8',
        ],
        path( __FILE__ )->openr_raw,
    ];
[download]

https://metacpan.org/pod/Plack::Response#body

here is the final code:

Correction ;)

my $app = sub {
    use Path::Tiny qw/ path /;
    use File::MimeInfo qw/ mimetype /;
    
    my $env         = shift;
    my $path_file = 'win.iso';
    
    my $content_type = mimetype($path_file) || 'application/octet-stre
+am';
    
    my $basename = path($path_file)->basename;
    $basename =~ s{[^\w\.-]+}{_}g;
    
    my $filehandle = path($path_file)->openr_raw ;
        
    return [
        200,
        [
            'Content-Type'        => $content_type,
            'Content-Length'        => -s $filehandle,
            'Content-Disposition' => qq[attachment; filename="$basenam
+e"],
        ],
        $filehandle
    ];
};
[download]

Ehh, that's what I get for not testing my submission.

Comment out these lines:

    my $content = path($path_file);
    my $content_download = $content->slurp;
[download]

Hi, yes I did that before to run.