There is a full implementation of try-catch block using perl filters

Source filters are unfortunately quite dangerous, they are very prone to making code extremely brittle (Update: for example, Switch was removed from the Perl core for that reason, see e.g. Perl Code Changes Behavior if Two Subroutine definitions are swapped). Note that there is currently development underway to add try/catch to Perl natively - see Adding a try/catch syntax to Perl and Progress on try/catch.

they are very prone to making code extremely brittle

Yes, it is true, but it largely depends on what the change are and how they are made. In the case of Nice::Try, the changes are carefully implemented and minimal and the module relies on PPI, which is way much safer than using regular expression. Anyway, try it, and you will see it is quite stable, but if you have any suggestion for improvement, I would very much welcome it.

Anyway, try it, and you will see it is quite stable, but if you have any suggestion for improvement, I would very much welcome it.

Yes, sorry, I wasn't doubting the quality of the implementation of Nice::Try. Though PPI is certainly excellent, like all static Perl parsers it can't actually parse all of Perl. Sadly, all source filters suffer from the fact that they can be broken by things outside of their control, namely, the source code that they are inserted into.

With Perl 5.34:

use warnings;
use strict;
use experimental 'try';

print foo();  # prints "Caught an error: Argh..."

sub foo {
    try {
        die( "Argh...\n" );
    }
    catch( $wow ) {
        return( "Caught an error: $wow" );
    }
}
[download]

PPI is in no way robust enough for this use case. Source filters will never be appropriate for production use.

use strict;
use warnings;
use experimental 'signatures';
use Nice::Try;

sub foo { 1 }
try {
  my $k = sub ($f = foo()) {};
}
catch ($e) {
  warn "caught: $e";
}
__END__
Global symbol "$e" requires explicit package name (did you forget to d
+eclare "my $e"?) at bad-syntax.pl line 10.
syntax error at bad-syntax.pl line 10, near ") {"
Execution of bad-syntax.pl aborted due to compilation errors.
[download]

The module has other serious issues:

use strict;
use warnings;
use Nice::Try;

{
  package MyException;
  use overload '""' => 'message';
  sub message { $_[0]->{message} }
  sub new { my $class = shift; bless { @_ }, $class }
  sub throw { my $class = shift; die $class->new(message => shift) }
}

try {
  MyException->throw("hi\n");
}
catch (MyException $e) {
  warn "working catch: $e";
}
catch ($e) {
  warn "broken catch: $e";
}
__END__
$ perl bad-exception.pl
broken catch: hi at bad-exception.pl line 21.
[download]