You don't need all those double quotes in the regexes. On the left-hand side, they're being taken literally, so just remove them, and on the right-hand side, you need them because of the /e modifier, but since you're not actually making use of that, get rid of the /e modifier and the double quotes on the right-hand side. In other words, s/=/="/ and s/\n/"\n/ (or s/$/"/ for the latter). No need for the /gs modifiers either.

However, the solution as you've currently written it seems brittle to me: In particular, it'll replace any equals sign. Personally, I'd either see if there is an existing module to parse whatever file format this is, and if there isn't, I'd try to parse the values myself, maybe something like the following. Note how you can extend the regex to do more, like for example I've designed it so that it won't add double quotes if there are already double quotes around the string, and reject the input if those double-quotes are unbalanced.

use warnings;
use strict;
use Test::More;

my $string=qq{parameter=TO_DATE('1900-01-01','YYYY-MM-DD')\n};

my $REGEX = qr{^ (\w+) = (?| "(.+)" | ( (?!").+(?<!") ) ) (\n|\z) }x;
if ( $string =~ $REGEX ) { $string = qq{$1="$2"$3} }
else { die "failed to parse $string" }

is $string, qq{parameter="TO_DATE('1900-01-01','YYYY-MM-DD')"\n};

done_testing;
[download]

getting rid of all the escaping, extra quotes and the e and s options worked. thank you

  DB<8> $_= "parameter=TO_DATE('1900-01-01','YYYY-MM-DD')\n"

  DB<9> s/=/="/

  DB<10> s/\n/"\n/

  DB<11> p $_
parameter="TO_DATE('1900-01-01','YYYY-MM-DD')"

  DB<12>
[download]

But I'd rather suggest using split /=/ and join on individual lines, using your regexes on a complete file will cause havoc if the RHS contains any '='.

You're overcomplicating things perhaps . . .

$ perl -E '$_=qq{parameter=TO_DATE('1900-01-01','YYYY-MM-DD')\n};print
+ qq{Before: $_};s{=(.*)$}{="$1"};print qq{ After: $_}'
Before: parameter=TO_DATE(1900-01-01,YYYY-MM-DD)
 After: parameter="TO_DATE(1900-01-01,YYYY-MM-DD)"
[download]

I came up with the same approach but you don't even need that $ because the dot doesn't match the newline by default.

use strict;
use warnings;

use Test::More tests => 1;

my $have = qq#parameter=TO_DATE('1900-01-01','YYYY-MM-DD')\n#;
my $want = qq#parameter="TO_DATE('1900-01-01','YYYY-MM-DD')"\n#;

$have =~ s/=(.*)/="$1"/;
is $have, $want;
[download]

---

🦛

I'm sorry -- why doesn't this work?:

s/=(.*)/="\1"/;
[download]

It works, but using a backreference \1 in place of a capture variable $1 in the replacement string is Frowned Upon and will earn you a warning:

Win8 Strawberry 5.8.9.5 (32)  Thu 01/28/2021 14:55:21
C:\@Work\Perl\monks
>perl -Mstrict -Mwarnings

use Data::Dump qw(dd);

my $s = "parameter=TO_DATE('1900-01-01','YYYY-MM-DD')\n";
dd 'before:', $s;

$s =~ s/=(.*)/="\1"/;
\1 better written as $1 at - line 7.
dd 'after:', $s;

^Z
("before:", "parameter=TO_DATE('1900-01-01','YYYY-MM-DD')\n")
(
  "after:",
  "parameter=\"TO_DATE('1900-01-01','YYYY-MM-DD')\"\n",
)
[download]

---

Give a man a fish:  <%-{-{-{-<

You need "=" in substitution field. Replace "\1" with "$1" per warnings.

use strict;
use warnings;
use Test::Simple tests=>1;

my $input_string = qq(parameter=TO_DATE('1900-01-01','YYYY-MM-DD')\n);
my $desired_output = qq(parameter="TO_DATE('1900-01-01','YYYY-MM-DD')"
+\n);

my $output = $input_string =~ s/=(.*)/="$1"/r;

ok( $output eq $desired_output, $output );
[download]

OUTPUT:

1..1
ok 1 - parameter="TO_DATE('1900-01-01','YYYY-MM-DD')"
#
[download]

Bill

You need "=" in substitution field.

And I had it. What's your point?