Re: How to trim a line from leading and trailing blanks without using regex or non-standard modules

G'day likbez,

I will usually reach for one of Perl's string handling functions (e.g. index, rindex, substr, and so on) in preference to a regex when that is appropriate; however, in this case, I would say that the regex makes for much cleaner code.

You could implement a trim() function using the guts of this code (which uses neither a regex nor any modules, standard or otherwise):

$ perl -E '
    my @x = ("  a b c ", "d  e f  ", " g h  i", "j k l", " ", "");

    say "*** Initial strings ***";
    say "|$_|" for @x;

    for my $i (0 .. $#x) {
        my $str = $x[$i];

        while (0 == index $str, " ") {
            $str = substr $str, 1;
        }

        my $str_end = length($str) - 1;

        while ($str_end == rindex $str, " ") {
            $str = substr $str, 0, $str_end;
            --$str_end;
        }

        $x[$i] = $str;
    }

    say "*** Final strings ***";
    say "|$_|" for @x;
'
*** Initial strings ***
|  a b c |
|d  e f  |
| g h  i|
|j k l|
| |
||
*** Final strings ***
|a b c|
|d  e f|
|g h  i|
|j k l|
||
||
[download]

If your question was genuinely serious, please Benchmark a trim() function using something like I've provided against another trim() function using a regex. You could obviously do the same for ltrim() and rtrim() functions.

[As others have either asked or alluded to, please explain phrases such as "definitely an overkill", "important special case" and "abuse of regex". Unfortunately, use of such language makes your post come across as some sort of trollish rant — I'm not saying that was your intent, just how it presents itself.]

— Ken

Comment on Re: How to trim a line from leading and trailing blanks without using regex or non-standard modules Select or Download Code

Replies are listed 'Best First'.
Re^2: How to trim a line from leading and trailing blanks without using regex or non-standard modules by LanX (Saint) on Aug 14, 2020 at 11:22 UTC
Hi Ken I suppose your solution works only for blank `" "` and not for other whitespace characters like `"\n"` So it's not exactly the same like with `\s` ° `DB<11> $a="x \n \n \n " DB<12> $a =~ s/\s+$// DB<13> x $a 0 'x' DB<14>` [download] The OP should be clearer about the semantics he wants. Cheers Rolf _{(addicted to the Perl Programming Language :) Wikisyntax for the Monastery} see also Re: How to trim a line from leading and trailing blanks without using regex or non-standard modules	[reply] [d/l] [select]
Re^3: How to trim a line from leading and trailing blanks without using regex or non-standard modules by kcott (Archbishop) on Aug 15, 2020 at 11:02 UTC
G'day Rolf, That's a valid point. My main intent with that code was really to show the complexity of the solution when a regex or module were not used. Anyway, adding a little more complexity, you can trim whatever blanks you want: $ perl -E ' my @blanks = (" ", "\n", "\r", "\t"); my @x = ( " a b c ", "d e f \r ", " \t g h i", "j k l", " ", "\n", "\n\nXYZ\n\n", "" ); say "* Initial strings "; say "\|$_\|" for @x; for my $i (0 .. $#x) { my $str = $x[$i]; while (grep { 0 == index $str, $_ } @blanks) { $str = substr $str, 1; } my $str_end = length($str) - 1; while (grep { $str_end == rindex $str, $_ } @blanks) { $str = substr $str, 0, $str_end; --$str_end; } $x[$i] = $str; } say " Final strings "; say "\|$_\|" for @x; ' Initial strings * \| a b c \| \| e f \| g h i\| \|j k l\| \| \| \| \| \| XYZ \| \|\| * Final strings * \|a b c\| \|d e f\| \|g h i\| \|j k l\| \|\| \|\| \|XYZ\| \|\| [download] You're quite correct about "The OP should be clearer ...". The word 'blank' is often used to mean various things: a single space, multiple consecutive spaces, a whitepace character, multiple consecutive whitepace characters, and I have also seen it used to refer to a zero-length string. Similarly, the word 'space' can mean a single space, any gap between visible characters, and so on. So, as with many posts, we're left with guessing the most likely meaning from the context. My belief, that a regex is a better option, strengthens as the complexity of the non-regex and non-module code increases. :-) — Ken	[reply] [d/l]


go ahead... be a heretic
	PerlMonks