I made a few changes to the conditionals around the eval code to possibly keep mistakes from happening when it is used, but I still can't figure out how to convert the eval EXPR into an eval BLOCK. Like converting a map or grep EXPR to a BLOCK, it isn't as easy as putting {} around it instead of () and expecting it to work the same.

  if ($raw_value && $raw_value =~ /\d+\*\d+/) {
    $total_value = eval($raw_value); # performs multiplication
    ($amount, $base_value) = split(/\*/,$raw_value);
  }
  elsif ($raw_value && $raw_value =~ /\d+\/\d+/) {
    $base_value = eval($raw_value); # performs division
    ($total_value, $amount) = split(/\//, $raw_value);
  }
  else {
    $amount = $raw_value;
    $base_value = $assets->{$lookup_asset} ? $assets->{$lookup_asset} 
+: 0;
    $total_value = $amount * $base_value;
  }
[download]

Are the numerical parts of $raw_value positive integers? If so, it's going to be simpler and (I suspect) more efficient to use capture groups and do the maths by hand. eg:

#!/usr/bin/env perl 
use strict;
use warnings;

my $raw_value = shift @ARGV;
my ($total_value, $base_value, $amount);
my $assets = {};
my $lookup_asset = 'foo';

  if ($raw_value && $raw_value =~ /(\d+)\*(\d+)/) {
    $total_value = $1 * $2; # performs multiplication
    ($amount, $base_value) = ($1, $2);
  }
  elsif ($raw_value && $raw_value =~ /(\d+)\/(\d+)/) {
    $base_value = $1 / $2; # performs division
    ($total_value, $amount) = ($1, $2);
  }
  else {
    $amount = $raw_value;
    $base_value = $assets->{$lookup_asset} ? $assets->{$lookup_asset} 
+: 0;
    $total_value = $amount * $base_value;
  }

print "Amount: $amount\nBase: $base_value\nTotal: $total_value\nRaw: $
+raw_value\n";
[download]

At least, that's how I would go about it.