#!/usr/bin/env perl
use warnings;
use strict;
use Benchmark qw/cmpthese/;

use feature 'state';
use Carp;
use Math::BigInt;
use Config;
use Regexp::Common qw/number/;

sub validate_int {
	my $str = shift;
	state $max = Math::BigInt->new(
		eval $Config{nv_overflows_integers_at} );
	croak "not an integer"
		unless defined $str && $str=~/\A$RE{num}{int}\z/;
	my $num = Math::BigInt->new($str);
	croak "integer to small" if $num < 0;
	croak "integer too big" if $num > $max;
	return $num->numify;
}

sub validate_int2 {
	my $str = shift;
	state $regex = do {
		my $max = eval $Config{nv_overflows_integers_at} or die;
		my $len1 = length($max) - 1;
		my $range = substr $max, 0, 1;
		$range = $range eq "1" ? "1" : "1-$range";
		qr{ \A (?: (?!0) [0-9]{1,$len1}
			| ( [$range] [0-9]{$len1} )
				(?(?{ Math::BigInt->new($^N)->bgt($max) })(*F))
		) \z }x };
	croak "bad integer" unless $str =~ $regex;
	return 0+$str;
}

sub validate_int3 {
	my $str = shift;
	state $max = int(eval $Config{nv_overflows_integers_at} or die);
	croak "not an integer" unless defined $str && $str=~/\A[0-9]+\z/;
	$str =~ s/\A0+(?=[1-9])//;
	croak "integer too big" if length $str > length $max
		|| sprintf("%0*s", length $max, $str) gt $max;
	return 0+$str;
}

my $max = eval($Config{nv_overflows_integers_at});

cmpthese(-2, {
	first => sub {
		validate_int(1)==1 or die;
		validate_int(999)==999 or die;
		validate_int($max-1)==$max-1 or die;
		validate_int($max)==$max or die;
		defined eval { validate_int($max+1) } and die;
	},
	second => sub {
		validate_int2(1)==1 or die;
		validate_int2(999)==999 or die;
		validate_int2($max-1)==$max-1 or die;
		validate_int2($max)==$max or die;
		defined eval { validate_int2($max+1) } and die;
	},
	third => sub {
		validate_int3(1)==1 or die;
		validate_int3(999)==999 or die;
		validate_int3($max-1)==$max-1 or die;
		validate_int3($max)==$max or die;
		defined eval { validate_int3($max+1) } and die;
	},
});

__END__

          Rate  first second  third
first   4544/s     --   -70%   -90%
second 15386/s   239%     --   -67%
third  46631/s   926%   203%     --