I also used a "fancy" trick with $cursor as ref to the @coor array.

(EDIT: Of course there is still more room for improvement, it depends if clarity or speed matters)

use strict;
use warnings;
use Data::Dump qw/pp dd/;
use Test::More;


sub matrix2 (&@){
    my $code = shift;

    my @coor;
    my $depth = @_;

    my $rec;
    $rec = sub  {

        return $code->(@coor) unless @_;

        my $level  = $depth - @_;
        my $max    = shift;
        my $cursor = \$coor[$level];

        my $arr = [
                   map {
                       $$cursor = $_;
                       $rec->(@_)
                   } 0 .. $max
                  ];

        return $arr;
    };

    $rec->(@_);
}



my $a_matrix = matrix2 {"<@_>"} 3,2,1;



my @classic;
for my $x (0..3) {
    for my $y (0..2) {
        for my $z (0..1) {
            $classic[$x][$y][$z] = "<$x $y $z>";
        }
    }
}




is_deeply($a_matrix,\@classic,"same matrix");

pp \@classic;

done_testing;
[download]

ok 1 - same matrix
[
  [
    ["<0 0 0>", "<0 0 1>"],
    ["<0 1 0>", "<0 1 1>"],
    ["<0 2 0>", "<0 2 1>"],
  ],
  [
    ["<1 0 0>", "<1 0 1>"],
    ["<1 1 0>", "<1 1 1>"],
    ["<1 2 0>", "<1 2 1>"],
  ],
  [
    ["<2 0 0>", "<2 0 1>"],
    ["<2 1 0>", "<2 1 1>"],
    ["<2 2 0>", "<2 2 1>"],
  ],
  [
    ["<3 0 0>", "<3 0 1>"],
    ["<3 1 0>", "<3 1 1>"],
    ["<3 2 0>", "<3 2 1>"],
  ],
]
1..1
[download]

Sure, there are several ways to implement it. That's not what I'm actually interested in - from the usage point of view it doesn't matter too much. Such a piece of code is just not enough that would justify it's own module. If only any of these were available as an export!

Greetings,
-jo

$gryYup$d0ylprbpriprrYpkJl2xyl~rzg??P~5lp2hyl0p$

IMHO is the classic approach simple enough.

Especially if you only want dim 1 and 2, I'd rather prefer combining map.

> any of these were available as an export!

You might want to have a look at List::MoreUtils or PDL and CPAN modules referencing them in "See Also" or in their dependencies..

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

The PDL function ndcoords looks like it does what you need.

pdl> p ndcoords 3,3
[
 [
  [0 0]
  [1 0]
  [2 0]
 ]
 [
  [0 1]
  [1 1]
  [2 1]
 ]
 [
  [0 2]
  [1 2]
  [2 2]
 ]
]
[download]

use strict;
use warnings;
use Data::Dump qw/pp dd/;
use Test::More;

sub matrix3 (&@){
    my ($code,@dims) = @_;

    my @coor =(undef)x@dims;

    my $rec;
    $rec = sub  {
        my @dims =@_;

        return $code->(@coor) unless @dims;

        my $level  = - @dims;
        my $max    = shift @dims;
        my $cursor = \$coor[$level];

        my @arr;

        for ( 0 .. $max ) {
            $$cursor = $_;
            $arr[$_] = $rec->(@dims);
        }

        return \@arr;
    };

    return $rec->(@dims);
}



my $a_matrix = matrix3 {"<@_>"} 3,2,1;





my @classic;
for my $x (0..3) {
    for my $y (0..2) {
        for my $z (0..1) {
            $classic[$x][$y][$z] = "<$x $y $z>";
        }
    }
}




is_deeply($a_matrix,\@classic,"same matrix");

pp \@classic;

done_testing;
[download]