Hi gdmichaels and welcome to the Monastery!

I have struggled and failed with various modules to connect to S3 over the years including the one you mentioned. In my experience you need to either use Paws, or if you don't need the Full Monty, Net::Amazon::S3.

I use the latter most of the time. I was working on an upload script just this morning as a matter of fact:

    my $s3 = Net::Amazon::S3->new({
        aws_access_key_id     => $conf->{access_key},
        aws_secret_access_key => $conf->{secret_key},
    });

    my $bucket = $s3->bucket($conf->{ bucket });

    $log->info("Uploading $key to S3");

    $bucket->add_key($key, join("\n", @rows, ''))
        or $log->fatal($s3->err . ': ' . $s3->errstr);
[download]

If you explain your installation issues, someone can likely assist.

Hope this helps!

TBH, I've fallen back to using the aws command-line tool. I use my module IPC::Run3::Shell:

use warnings;
use strict;
use IPC::Run3::Shell [ aws => {fail_on_stderr=>1}, "/path/to/aws" ];
use Cpanel::JSON::XS qw/decode_json/;
use Data::Dumper;

my $PROFILE = 'MyProfile'; # aws configure --profile=MyProfile
my $buckets = decode_json( aws(qw/ s3api --output json --profile /,
    $PROFILE, 'list-buckets') );
print Dumper($buckets);
[download]

Update: See also.

I've been using AWS::CLIWrapper for some time. It has the advantage that you can do everything the CLI offers.

I've been using AWS::CLIWrapper for some time.

Thank you for pointing this out, it inspired me to release IPC::Run3::Shell::CLIWrapper, which is a more generic tool, but allows me to write my previous example as the following. The set-up may look a little more complicated, but the actual calls are much simplified. And since I wrote IPC::Run3::Shell, I can be certain of its behavior :-)

use warnings;
use strict;
use IPC::Run3::Shell::CLIWrapper;
use JSON::PP qw/decode_json/;
use Data::Dumper;

my $s3api = IPC::Run3::Shell::CLIWrapper->new( { fail_on_stderr => 1,
    stdout_filter => sub { $_=decode_json($_) } },
    qw/ aws --profile MyProfile --output json s3api /);

my $buckets = $s3api->list_buckets;
print Dumper($buckets);
[download]

Taking a real life example, I don't see an advantage in using IPC::Run3::Shell::CLIWrapper over AWS::CLIWrapper:

#!/usr/bin/perl

use strict;
use warnings;
use AWS::CLIWrapper;
use Data::Dumper;

my $aws = AWS::CLIWrapper->new(profile => 'my_profile') or
    die $AWS::CLIWrapper::Error->{Message};

sub gethosts {
    my $name = shift;
    my $hosts = $aws->ec2('describe-instances' => {
        filters => [{Name => 'tag:Name', Values => [$name]}],
        query => 'Reservations[*].Instances[*].{Id:InstanceId,Addr:Pri
+vateIpAddress,Zone:Placement.AvailabilityZone,Name:(Tags[?Key==`Name`
+])[0].Value}'}) or
            die "$AWS::CLIWrapper::Error->{Message}";
    return [map {@$_} @$hosts];
}
my $hosts = gethosts('*something*');
print Dumper($hosts);
[download]

Doesn't this feel very "perlish"? :-)
Maybe I'm missing the point.

Greetings,
-jo

$gryYup$d0ylprbpriprrYpkJl2xyl~rzg??P~5lp2hyl0p$