To add scrollbars, use the Tk::Scrolled. For example, you can create a top scrolled frame:

#!/usr/bin/perl
use warnings;
use strict;

use Tk;

my $mw = 'MainWindow'->new;

my @array = map join('=', int rand 100), 1 .. 100;
my $top = $mw->Scrolled('Frame', -scrollbars => 'e')->pack;

my $x = 0;
for my $pair (@array) {
    my ($name, $value) = split /=/, $pair;
    my $frame = $top->Frame->pack;
    my $label_index = $frame->Label(-text   => $x,
                                    -width  => 10,
                                    -relief => 'groove')
        ->pack(-side => 'left');
    my $label_name = $frame->Label(-text   => $name,
                                   -width  => 30,
                                   -relief => 'groove')
        ->pack(-side => 'left');
    my $label_value = $frame->Label(-text   => $value,
                                    -width  => 25,
                                    -relief => 'groove')
        ->pack(-side => 'left');
    my $label_description = $frame->Entry(-text  =>'description',
                                          -width => 30,
                                          -relief =>'groove')
        ->pack(-side=>'left');
    ++$x;
}

MainLoop();
[download]

Note that my example is runable as is, while yours isn't (I had to guess the format of the array values, etc.) Also, adding a space here or there improves readability.

The first argument of split is a regex or a space. Also, I prefer single quotes for strings that don't interpolate anything, and no quotes for strings that only interpolate a single variable.

Update: The array is populated wrongly. See Lotus1's reply for a fix.

I usually learn something from your code so I tend to read it carefully. I noticed that the join() inside the map() is only joining one item so there won't be a '='. When I run your example the third column is blank. The split /=/, $pair; section is only populating $name. I was able to fix it by placing a second int rand 100 inside the join().

After a few more tweaks I ended up with this:

#!/usr/bin/perl
use warnings;
use strict;

use Tk;
use Tk::Pane;

my $mw = 'MainWindow'->new;

my @array = map join('=', $_, int rand 100, int rand 100), 1 .. 100;
my $top = $mw->Scrolled('Frame', -scrollbars => 'e')->pack;

for my $pair (@array) {
    my ($x, $name, $value) = split /=/, $pair;
    print "pair=$pair, name=$name, value=$value\n";
    my $frame = $top->Frame->pack;
    my $label_index = $frame->Label(-text   => $x,
                                    -width  => 10,
                                    -relief => 'groove')
        ->pack(-side => 'left');
    my $label_name = $frame->Label(-text   => $name,
                                   -width  => 30,
                                   -relief => 'groove')
        ->pack(-side => 'left');
    my $label_value = $frame->Label(-text   => $value,
                                    -width  => 25,
                                    -relief => 'groove')
        ->pack(-side => 'left');
    my $label_description = $frame->Entry(-text  =>'description',
                                          -width => 30,
                                          -relief =>'groove')
        ->pack(-side=>'left');
}

MainLoop();
[download]

Thanks for the fix, I originally had a map inside a map there and wanted to simplify it, but didn't check the results or copied a wrong phase of the change.
map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]

As a side note, the lexicals  $label_index $label_name $label_value $label_description are scoped entirely within the for-loop of the OPed code and any values assigned to them vanish at the end of that loop. I assume you're saving these values into some structure in an enclosing scope, but if you're not, you can save your eyesight and fingertips by getting rid of them.

Also, your use of  @var and  $x in the (pseudo?) code suggests you're not using strict and warnings. If that's actually the case and not just an artifact of the example, use strict and warnings. :) The runnable example code of choroba and Lotus1 handle these variables "correctly" IMHO.