#!/usr/bin/perl
use strict;
use warnings;
use feature "say";

my @unsorted_array = qw( page1.html page11.html page2.html page3.html 
+);
say for sort {
    ($a =~ /([0-9]+)/)[0] <=> ($b =~ /([0-9]+)/)[0]
} @unsorted_array;
[download]

See: How do I sort an array by (anything)? in the Data: Arrays section of perlfaq4; and A Fresh Look at Efficient Perl Sorting.

See natkeysort in Sort::Key::Natural.

Sorting mixed strings

A GRT sort that casts non-compliant files to the top of the sorted list.

johngg@shiraz:~/perl/Monks$ perl -Mstrict -Mwarnings -E '
say for
   map { substr $_, 54 }
   sort
   map { pack q{a50Na50}, ( m{^([A-Za-z]+)(\d+)\.html$} ? ( $1, $2 ) :
+ ( q{}, 0 ) ), $_ }
   qw{ page1.html index2.html page11.html rubbish.html page3.html inde
+x1.html page2.html }'
rubbish.html
index1.html
index2.html
page1.html
page2.html
page3.html
page11.html
[download]

I hope this is of interest.

Update: A scripted version that constructs a sorted array and a rejects array. This code

use strict;
use warnings;

use feature qw{ say };

my @unsorted = qw{
   page1.html
   test4.txt
   index2.html
   page11.html
   rubbish.html
   page3.html
   index1.html
   page2.html
   garble.html
   page0.html
   };

my @sorted;
my @rejects;

push @{ ( m{^\xff{54}} ) ? \ @rejects : \ @sorted }, substr $_, 54 for
   sort
   map {
       pack q{a50Na50},
          ( m{^([A-Za-z]+)(\d+)\.html$}
            ? ( $1, $2 )
            : ( qq{\xff} x 50, -1 )
          ),
          $_
       }
   @unsorted;

say q{-} x 20;
say for @sorted;
say q{-} x 20;
say for @rejects;
say q{-} x 20;
[download]

outputs

--------------------
index1.html
index2.html
page0.html
page1.html
page2.html
page3.html
page11.html
--------------------
garble.html
rubbish.html
test4.txt
--------------------
[download]

Update 2: Added {54} quantifier to regex in above code, output unchanged.

A solution leveraging the inferred limit of a 2-digit number in the filename (just because TIMTOWTDI).

use strict;
use warnings;

use Test::More tests => 1;

my @arrayUnsorted = ('page1.html', 'page11.html', 'page2.html', 'page3
+.html');
my @arraySorted   = ('page1.html', 'page2.html', 'page3.html', 'page11
+.html');

my @have = sort { substr ($a, 4, 2) <=> substr ($b, 4, 2) } @arrayUnso
+rted;
is_deeply \@have, \@arraySorted;
[download]

@arrayUnsorted=('page1.html', 'page11.html', 'page2.html', 'page3.html
+');

my @a = sort{ ($a.$b)=~/(\d*)\.htmlpage(\d*)/;$1<=>$2; } @arrayUnsorte
+d;

print "$_\n"
  foreach @a;
[download]