Probably what you want is to do something like you’ve already got once while also setting up a watcher to handle only new/changed things. I have used Linux::Inotify2 and there are some other packages like File::ChangeNotify; I don’t have direct experience with that one but use it often in Catalyst testing with its tools.

Something like this? Untested !!

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11108019
use warnings;

my %processed;

while( 1 )
  {
  my %files = map +($_ => 1), glob '/root/fd/fg/*.txt';

  for my $file ( grep !$processed{$_}, keys %files )
    {
    # open and process $file here
    }
  %processed = %files; # clean up %processed

  sleep 10; # or some useful sleep time
  }
[download]

Warning - still Untested !!

Of course, if the directory is very dynamic, you might get files that are still being written (depending on your OS: for example, it wouldn't be possible to read a file that is being written under VMS, but that's entirely possible under most Unix/Linux flavors). That's not the question you asked, but it is often possible to find a delay that will prevent working on files being written.

You could keep a list of files that have been processed.
When a new file appears, process that new one.

Adjust your list of processed files as each new one comes in.
There can be some issues with this, please explain your application more.

First of all, i took the liberty of beautifying your code, removing the use of $_ in favour of named variables and added the use strict; use warnings; stuff that makes your code easier to debug. I also took the liberty of introducing the magic of use Carp; and use English;. Hope you are not angry about that ;-)

One way to mark files done is to add a second empty ".done" file and checking for that. If some other programs removes the .txt files, you could just as easy check for ".done" files without corresponding ".txt" files and remove them.

Here is a simple version of that (untested since i only had a few minutes and couldn't be bothered to recreate your directory structure):

#!/usr/bin/env perl

use strict;
use warnings;
use Carp;
use English;

# Do some work
foreach my $file ( glob('/root/fd/fg/*.txt') ) {
    next if(-f $file . '.done'); # Skip if '*.done' file exists

    open(my $ifh, '<', $file) or croak($ERRNO);

    my $ad;
    my @rt;

    while((my $line = <$ifh>)) {
        if($line =~ m/ad/) {
            ($line =~ tr/a-z,=//d ) ;
            $ad = $line ;

        }
        if ($line =~ m/rt /){
            ($line =~ tr/a-z,=//d) ;
            push (@rt , $line);
        }
    }

    close $ifh; # Need to close fille after working on it.

    open(my $ofh, '>', $file . '.done') or croak($ERRNO); # Create '*.
+done' file
    close($ofh);
}

# Cleanup
foreach my $file ( glob('/root/fd/fg/*.txt.done') ) {
    my $realfname = $file;
    $realfname =~ s/\.done$//;

    if(!-f $realfname) {
        unlink $file;
    }
}
[download]

If no other program works with the files after your program, you might as well just rename them.

#!/usr/bin/env perl

use strict;
use warnings;
use Carp;
use English;
use File::Copy;

# Do some work
foreach my $file ( glob('/root/fd/fg/*.txt') ) {

    open(my $ifh, '<', $file) or croak($ERRNO);

    my $ad;
    my @rt;

    while((my $line = <$ifh>)) {
        if($line =~ m/ad/) {
            ($line =~ tr/a-z,=//d ) ;
            $ad = $line ;

        }
        if ($line =~ m/rt /){
            ($line =~ tr/a-z,=//d) ;
            push (@rt , $line);
        }
    }

    close $ifh; # Need to close fille after working on it.

    # Rename/move file
    move($file, $file . '.done');
}
[download]

There is potentially another problem. If the external program that generates these files writes to a file while you are still reading it, you might get an incomplete read - which is damn hard to debug and can give you a lot of grey hairs. One workaround hack to that is to get the filelist, then wait a few seconds and then process the file list. Something like this should work:

...
# Do some work
my @files = glob('/root/fd/fg/*.txt');
sleep(4);
foreach my $file(@files) {
...
[download]