Your pastebinned code includes this line:

    my $dbh = @_;   # Case #2

This almost certainly doesn't do what you want as it enforces scalar context. Use list context instead:

    my ($dbh) = @_;   # Case #2
[download]

See the Context tutorial for more on this. In future, please include your code in the question (enclosed withing <code> ... </code> tags) rather than a transient off-site link.

Indeed it works. Thank you. But can you ten me, why my $dbh = $_[0] does not work?

That also works fine. SSCCE:

$ cat close.pl
#!/usr/bin/env perl 
use strict;
use warnings;
use DBI;

my $dbh = DBI->connect ('dbi:SQLite:dbname=foo', '', '');

close_db ($dbh);

sub close_db {
    my $dbh = $_[0];
    $dbh->disconnect or die "Could not disconnect: $DBI::errstr\n";
}
$ perl close.pl
$
[download]

The idiom as I understand for extracting function arguments into lexicals is: my $var = shift;

Sample code:

use strict;
use warnings;

sub quux {
    my $foo = shift;
    my $bar = shift;
    my $baz = shift;

    print "FOO:$foo BAR:$bar BAZ:$baz\n";
}

quux(1, 2, 'three');
quux(one => 2, 3);  # illustrate "fat comma"
[download]

Sample output:

FOO:1 BAR:2 BAZ:three
FOO:one BAR:2 BAZ:3
[download]

Generally, you should use one of these idioms near the very beginning of each sub to bring your arguments into lexicals. There is usually little difference between assigning @_ to a list of variables and using shift, but sometimes it can matter, particularly if you have additional arguments to process. You can also use splice on @_ to extract a group of arguments into a list of variables or an array, but this is a more advanced feature. Directly accessing elements of @_ is best limited to very short subs, with a comment listing the arguments nearby.

The "fat comma" is another neat Perl feature. You can think of it as quoting the previous word (there are some fairly complex rules for what gets quoted, but in most contexts it Just Works) and acting exactly like a normal comma in every other way. You will see it often in keyword arguments in many Perl modules. See the "Comma Operator" section in perlop for details.