http://qs321.pair.com?node_id=11100402

Anonymous Monk has asked for the wisdom of the Perl Monks concerning the following question:

Hi Monks,

I have a function with should select files by a given list of extension. I wrote a program, which did not work. After playing a little around I found a working solution (using a local variable: my $x). But I do not understand, why my first version is not working.

Can you help me explaining the difference between this two versions:

In the first version the expression(@ext) is replaces by '1';

In the second version the expression(@ext) is correct. ('f.*\\.txt$', 'f.*\\.txt.*$')

Thanks for your help !!!


use strict;
use warnings;
use Data::Dumper qw(Dumper);
$\="\n"; 

my @ext;
my @list=('f1.txt','f2.txtx','f3.xtxt','x1.txt');
my  $ex="f*.txt,f*.txt*";

print " Version 1: Not working--------------------------------";
@ext=map { $_=quotemeta($_).'$'; s/\\\*/.*/;} split(/,/,$ex);         
+  # <<<<<< compare this line
print "qr=".Dumper(\@ext);
foreach my $e(@ext)
{ foreach my $f(@list) {print "Match: ($e) => $f" if ($f=~m/$e/); }}

print " Version 2: working--------------------------------";
@ext=map { my $x=quotemeta($_).'$'; $x=~s/\\\*/.*/g; $_=$x;} split(/,/
+,$ex);  # <<<<<< compare this line
print "qr=".Dumper(\@ext);
foreach my $e(@ext)
{ foreach my $f(@list) {print "Match: ($e) => $f" if ($f=~m/$e/); }}

[download]

Replies are listed 'Best First'.
Re: Why do I need a local variable in map function
by haukex (Archbishop) on May 23, 2019 at 07:41 UTC

    s/// returns the number of substitutions made, so that's what that map block is returning. Although it's generally not considered good practice to modify the original list by modifying or assigning to $_ in a map block, the first version could be written as map { $_ = quotemeta($_) . '$'; s/\\\*/.*/g; $_ } to achieve the desired result. Alternatively, as of Perl 5.14, you can say s///r to have the regex return the modified string, e.g. map { my $x = quotemeta($_) . '$'; $x =~ s/\\\*/.*/gr }.

    Update: Note that your second regex includes /g, while your first one does not; I've added it to both my examples.

    Update 2: Or even just map { quotemeta($_).'$' =~ s/\\\*/.*/gr } or map { "\Q$_\E\$" =~ s/\\\*/.*/gr }

[reply]
[d/l]
[select]
      Thanks for the perfect answer.
[reply]

Back to Seekers of Perl Wisdom