Re^5: processing file content as string vs array

I like your code and have no problem with it!

There are a number of techniques to deal with this kind of parsing. I know how to implement several of them and I'm ok with them all.

Your example data format is unusual because it has more than one significant complicating factor.

Just for fun, I show an alternate coding that demo's some other techniques. I make no claim about "better". There is seldom a coding pattern that works "the best" in all situations. I used your regex'es as they looked fine to me. At the end of the day, all of the "states" have to be described and handled.

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;
$|=1;

# Don't read in another line if we are still working
# on a START line. This is caused by the
# X START Y syntax in conjunction with the idea
# of END absent a START in this example file format.

# As a thought redefining the input separtator to
# be 'START' could possibly be productive if the format
# is not exactly like this?,

# This format has some of the nastiest things to deal
# with. They normally do not occur all at once!


my @record=();
my $line_in ='';

while ( $line_in =~ /START/ or $line_in =<DATA>)
{      
    $line_in =  construct_record($line_in) if $line_in =~ /START/;
}


sub construct_record
{
    my $line = shift;
    
    if ( (my $x) = $line =~ /START\s+(\w+)\s*$/)
    {
       push @record, $x;
    }

    while (defined ($line = <DATA>) and ($line !~ /(START|END)/) )
    {
        $line =~ s/^\s*|\s*$//g;
        push @record, $line;
    }
    
    $line //= '';  #could be an EOF
  
    if (my ($b4end) = $line =~ /^ (?: (.+) \s+ )? END $/x)
    {
        push @record, $b4end if $b4end;
        output_record();
        return '';  # no continuation of this record
    } 
    if ( my ($x,$y) = $line =~ /^ (?: (.+) \s+ )? START (?: \s+ (.+) )
+? $/x )
    {
        if ($x)
        {
           push @record, $x; 
           output_record();  
        }
        if ($y)
        {
            output_record();  # might be: "^START 77"?
            return "START $y";
        }
     }   
     return '';
}

sub output_record  # or process it somehow...
{
    print "Record: @record\n" if (@record >1);
    @record=();
}

=Prints
Record: a b
Record: c d e f g
Record: h i
Record: j k
=cut


__DATA__
START
a
b
START c
d
e
f
g END
ignoreme
START h
i START j
k
END
[download]

Comment on Re^5: processing file content as string vs array Download Code

Replies are listed 'Best First'.
Re^6: processing file content as string vs array by haukex (Archbishop) on May 21, 2019 at 16:04 UTC
Of course TMTOWTDI. I just don't see the advantage of this code over just inlining the `sub construct_record` code directly in the `while` loop. Plus, you've increased the number of global variables you're using. There are a couple other things I could nitpick, like that you've got five different regexes all checking for the string `START`. This format has some of the nastiest things to deal with. They normally do not occur all at once! I disagree - I don't find this format nasty and there are plenty of data formats this complicated. Which was exactly my point - a state machine type approach can handle them all. Anyway, as I said, as long as it works you're free to write code like this - I personally still disagree with it `;-)`	[reply] [d/l] [select]
Re^7: processing file content as string vs array by Marshall (Canon) on May 21, 2019 at 16:26 UTC
I don't want to get into a big argument. My purpose was to show TMTOWTDI. I do not claim that the approach I demo'ed works best for all cases. I think knowledge of multiple ways to implement this result is a good idea. I do agree that a state machine approach can handle much more complicated formats than in this example. Most of the formats I deal with are less complex (thank goodness!) and do not require a state_machine approach.	[reply]


Don't ask to ask, just ask
	PerlMonks