Sorting Complex Data Structure

Anonymous Monk has asked for the wisdom of the Perl Monks concerning the following question:

Dear keepers of Perl knowledge,

I'm working with a quite complex data structure (I think it's a array of arrays of hashes) and I need sort the results before printing. I can access each element by using @Data[$_]{ID}, @Data[$_]{Score} and looping through the number of elements.

The issue lies in the fact that I need to sort by Score and then group the results of same IDs together based on the score of the top hit with a given ID. Example:

ID: AA Score: 20
ID: D  Score: 30
ID: F  Score 7
ID: AA Score: 3
[download]

The results should look like:

ID: D  Score: 30
ID: AA Score: 20
ID: AA Score: 3
ID: F  Score 7
[download]

I thought about creating additional, separate hash, sorting by score, printing the 1st one and looping looking for all other with same ID (I would need to delete everything I use in the process to avoid redundancies). I presume there must a more straight forward and elegant solution. Thanks for your help.

Comment on Sorting Complex Data Structure Select or Download Code

Replies are listed 'Best First'.

Re: Sorting Complex Data Structure
by choroba (Cardinal) on Jan 21, 2014 at 13:27 UTC

my %by_id;
push @{ $by_id{ $_->{id} } }, $_->{score} for @data;

# Sort the scores for each id.
$_ = [ sort { $b <=> $a } @$_ ] for values %by_id;

# Sort the ids by the highest score.
for my $id (sort { $by_id{$b}[0] <=> $by_id{$a}[0] } keys %by_id) {
    print "ID: $id\tScore: $_\n" for @{ $by_id{$id} };
}
[download]

لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ

[reply]
[d/l]

Re^2: Sorting Complex Data Structure

by Anonymous Monk on Jan 21, 2014 at 14:30 UTC

Hi choroba,

Thanks that seemed to do the trick. The remaining issue is that I have a lot of other features saved in the original data structure (that varies depending on task). Is there a way to perhaps link this with the original array indexes, save the order and then print it using this order? Thanks again

[reply]

Re: Sorting Complex Data Structure
by Corion (Patriarch) on Jan 21, 2014 at 13:20 UTC

This is a FAQ. See perlfaq4 on How do I sort an array by (anything)?

[reply]

Re: Sorting Complex Data Structure
by ww (Archbishop) on Jan 21, 2014 at 14:15 UTC

"I think it's a array of arrays of hashes"

Perhaps you should use Data::Dumper or some other technique to confirm or rebut that thought.

[reply]

Re^2: Sorting Complex Data Structure

by derby (Abbot) on Jan 21, 2014 at 14:35 UTC

ww++. This is the only reasonable answer ... until you know what the data structure is, all the other solutions are just throwing code at the wall to see what sticks.

-derby

[reply]

Re^2: Sorting Complex Data Structure

by Anonymous Monk on Jan 21, 2014 at 15:33 UTC

Hi, I've used the data dumper before - it's array of array of hashes and chorobas code works. Thanks

[reply]

Re^3: Sorting Complex Data Structure

by Athanasius (Archbishop) on Jan 22, 2014 at 01:38 UTC

From the OP:

I can access each element by using @Data[$_]{ID}, @Data[$_]{Score}...

I assume this was a misprint for $Data[$_]{ID}, $Data[$_], since you are accessing single elements, not array slices.

it's array of array of hashes and chorobas code works.

Here is how choroba’s code works for me:

use strict;
use warnings;

my @data =
(
    { ID => 'AA', Score => 20 },
    { ID => 'D',  Score => 30 },
    { ID => 'F',  Score =>  7 },
    { ID => 'AA', Score =>  3 },
);

## choroba's solution:

my %by_id;
push @{ $by_id{ $_->{ID} } }, $_->{Score} for @data;

# Sort the scores for each id.
$_ = [ sort { $b <=> $a } @$_ ] for values %by_id;

# Sort the ids by the highest score.
for my $id (sort { $by_id{$b}[0] <=> $by_id{$a}[0] } keys %by_id) {
    print "ID: $id\tScore: $_\n" for @{ $by_id{$id} };
}
[download]

As you can see, there is only one array; i.e., @data is an array of hashes (AoH).

Hope that helps,

Athanasius <°(((>< contra mundum Iustus alius egestas vitae, eros Piratica,

[reply]
[d/l]
[select]


We don't bite newbies here... much
	PerlMonks