note
smls
<h3>Non-recursive solution</h3>
<p>For completeness, here's a solution that does <i>not</i> use a recursive subroutine:</p>
<code>
sub nested_foreach(&@) {
my $code = shift;
my @indices = map { 0 } @_; # First set of indices is all zeroes
my @sizes = map { scalar @$_ } @_; # Cache array sizes (optional)
my $k;
do {
# Determine the array elements corresponding to the current set
# of indices, and pass them to the closure:
$code->( map { $_[$_][$indices[$_]] } 0..$#_ );
# Determine the next set of indices:
for ($k = $#_; $k >= 0; $k--) {
$indices[$k]++;
if ($indices[$k] < $sizes[$k]) { last; }
else { $indices[$k] = 0; }
}
# If $k went out-of-bounds, there are no more valid iterations:
} while ($k >= 0);
}
my @a = ...;
my @b = ...;
my @c = ...;
nested_foreach { say join ' ', @_ } \@a, \@b, \@c;
</code>
<p>The "<i>Determine the next set of indices</i>" step may seem a little complicated at first sight, but it becomes more intuitive if you think of the <code>@indices</code> array as an integer number (with each element representing a digit), and imagine that we want to "increment" that "number" by 1. It's not a decimal (i.e. base-10) number, but rather one where each digit can have a different base (i.e. the sizes of the input arrays) - but that doesn't really change anything.</p>
<p>Incrementing the "number" by 1 works just like the <b>integer addition</b> <i>(here with an addend of 1)</i> that you were taught back in primary school: Start with the right-most digit; increment it; if it's still within the valid range of digits then you're done; if instead it went above the limit then wrap it around to zero, "carry the one", and repeat the same steps with the next digit to the left.</p>
<hr>
<p><i>Update:</i></p>
<h3>Performance comparison</h3>
<p>Interestingly, my iterative solution seems to be significantly <b>slower</b> than [id://1064678|BrowserUK's recursive solution], at least when running on my PC and with various different numbers/sizes of input arrays I tried:</p>
<code>
sub nested_foreach(&@) {
... # see above
}
sub nForX(&@) {
... # see BrowserUK's post
}
# my @size = (500, 900);
# my @size = (5, 5, 5, 5, 5, 5, 5, 5);
my @size = (100, 4, 75, 23);
my @AoA = map { [map { chr($_+64) x int(rand(10)) } 1 .. $_] } @size;
cmpthese -10, {
iterative => sub { nested_foreach { join("", @_) } @AoA },
recursive => sub { nForX { join("", @_) } scalar @AoA, @AoA },
};
</code>
<code>
s/iter iterative recursive
iterative 1.86 -- -71%
recursive 0.532 249% --
</code>
1064607
1064607