ravi06,
I thought, a chapter should be a subset of a book and not the other way round? However, if you are sure of what you wanted, knowing that the key of hash MUST be unique, then you can do like so:

use warnings;
use strict;
use Data::Dumper;

my %book = (
'name' => 'abc',
'author' => 'monk',
'isbn' => '123-890',
'issn' => '@issn',           
);

my %chapter = (
'title' => 'xyz',
'page' => '90',                
);

## VOIR HERE
my @temp_arr = keys %book;
@chapter{@temp_arr} = @book{@temp_arr};

print Dumper \%chapter;

print $/, $chapter{name},$/;  #prints abc
[download]

Calls to keys and values are guaranteed to return data in a consistent way, so you could simply write:

@chapter{ keys %book } = values %book;
[download]

The closest I can think of is this:

use strict;
use warnings;

my %book = (
        'name' => 'abc',
        'author' => 'monk',
        'isbn' => '123-890',
        'issn' => '@issn',           
        );

my %chapter = (
        'title' => 'xyz',
        'page' => '90',                
        );

$chapter{book} = \%book;

print $chapter{book}{name},"\n";
[download]

As others have also pointed out, you cannot transparently 'inherit' one hash from another; but wouldn't

print $chapter{book}{name};
[download]

Be both acceptable and superior as its clear that it's the book's name, not the chapter's name, being printed

(Also, you could then use 'title' for both the title of the book and the title of the chapters if you wanted to):

#! perl -slw
use strict;

my %book = (
    'name' => 'abc',
    'author' => 'monk',
    'isbn' => '123-890',
    'issn' => '@issn',
);

my %chapter = (
    'book' => \%book,
    'title' => 'xyz',
    'page' => '90',
);

print $chapter{book}{name};

__END__
C:\test>junk82
abc
[download]

The only possibility to make %chapter act as a proxy for %book is using hash ties.

I won't go into details since this is certainly a XY problem!

Most probably you just need to copy

%chapter=(%chapter,%book)

Why not just merge the two hashes? Are the keys unique? Is there anything to link the hashes together e.g ISBN or unique book ID?

I would flip the data model around. One book may contain multiple chapters. They will also normally be sequentially numbered so I'd make an array of them.

#!/usr/bin/perl
use strict;
use warnings;

my %book = (
    name    => 'ABC - an adventure',
    author  => 'monk',
    isbn    => '123-890',
    issn    => '@issn',
    chapter => [],
);

$book{chapter}[1] = {
    name => 'Testing Times',
    page  => 2,
};

$book{chapter}[2] = {
    name => 'Importing Hash',
    page => 99,
};

print "$book{name}\n";

my $i = 1;
while (exists $book{chapter}[$i]) {
    print "Ch: $i '$book{chapter}[$i]{name}' ($book{chapter}[$i]{page}
+)\n";
    $i++
}
[download]

ABC - an adventure
Ch: 1 'Testing Times' (2)
Ch: 2 'Importing Hash' (99)
[download]

Cheers,
R.

I'm sure there is a similar path via perlintro

%chapter = 
( 
    'book'=> {
        'name' => 'abc',
        'author' => 'monk',
        'isbn' => '123-890',
        'issn' => '@issn',        
    },
    'title' => 'xyz',
    'page' => '90',   
);

$value = $chapter{'book'}{'name'};
print ":$value:";
[download]

Maybe there is a way. You could create a tied hash which looks up key/values somewhere else if they are not present.

However that's something I definitely do not recommend at all. This way lies loss of sanity and lots of hairpulling.

Yes. I am sure about the data model.