#!/usr/bin/perl
use strict;
use warnings;
use Text::ParseWords;

my $text; do {local $/; $text = <DATA>};
my  @words = quotewords('\s+', 1,$text);

my $i = 0;
foreach (@words) {
      if (/^".+"$/s) {
        printf "<%s> : COUNT %d\n", $_, scalar split;
      }
}

__DATA__
"Yes, yes, how was it now?" he thought, going over his dream.
"Now, how was it? To be sure! Alabin was giving a dinner at
Darmstadt; no, not Darmstadt, but something American.  Yes, but
then, Darmstadt was in America.  Yes, Alabin was giving a dinner
on glass tables, and the tables sang, _Il mio tesoro_--not _Il mio
tesoro_ though, but something better, and there were some sort of
little decanters on the table, and they were women, too," he
remembered.
[download]

C:\Old_Data\perlp>perl t33.pl
<"Yes, yes, how was it now?"> : COUNT 6
<"Now, how was it? To be sure! Alabin was giving a dinner at
Darmstadt; no, not Darmstadt, but something American.  Yes, but
then, Darmstadt was in America.  Yes, Alabin was giving a dinner
on glass tables, and the tables sang, _Il mio tesoro_--not _Il mio
tesoro_ though, but something better, and there were some sort of
little decanters on the table, and they were women, too,"> : COUNT 66
[download]

my $count;
foreach (@words) {
  my $quote = ($_ eq '"');
  if ($quote ... $quote) {
    if (!$quote) { $count++ }
    elsif ($count) { print "$count quoted words\n"; $count = 0 }
  }
}
[download]

use File::Slurp;
my $text = read_file('input.txt');

while ($text =~ /" (.*?) "/sg) {
  print "Found quoted string with ".split(' ', $1)." words: $1\n";
}
[download]

Thanks! I ended up going with this solution as it is easy to read and allows me to get other data about the entire text using regex's.

If you just want the count of all white space words within double quotes in a text file, you don't need to keep much information hanging around. Try filtering:

perl -E 'say 0+map{split}grep{$i++%2}split/"/,do{undef$/;<>};' fil.txt
[download]

(Please pardon the golfing, I have this thing about keeping one-liners on one line ;-)

Mwahahahaha

#!/usr/bin/perl --
#~
#~
#~
#~ # perltidy -olq  -csc -csci=10 -cscl="sub : BEGIN END if " -otr -op
+r -ce -nibc -i=4 -pt=0   "-nsak=*"
#!/usr/bin/perl --
use strict;
use warnings;
use autodie;    # error checking for open/close...

Main( @ARGV );
exit( 0 );

sub Main {
    my( @files ) = @_;
    if( not @files ) {
        my $lines = q{ And "then" something "happened" on "the first
and second
and third
lines" and then it was over};
        @files = ( \'"the boat"', \$lines, \"$lines $lines $lines" );
    }
    for my $file ( @files ) {
        print "## { $file }{ wordcount= ", Vote( $file ), " }\n";
    }
} ## end sub Main

sub Vote {
    my( $fyle ) = @_;

    open my( $wyld ), '<:raw', $fyle;

    my $in_quotes = 0;
    my $words     = 0;

    while( my $line = readline $wyld ) {
        pos( $line ) = 0;
      WORDCOUNTER:
        while( length( $line ) > pos( $line ) ) {
            $line =~ m{
                \G\s*\x22  # quote after optional whitespace
            }gxcs and do {
                $in_quotes = !$in_quotes;    ## flip it
                next WORDCOUNTER;
            };

            $in_quotes and $line =~ m{
                [^\x22\s]+ ## not quote or whitespace
            }gxcs and do {
                $words++;
                next WORDCOUNTER;
            };

            $line =~ m{
                \G[^\x22]+ ## not quote
            }gxcs and do {
                next WORDCOUNTER;
            };
        } ## end of WORDCOUNTER
    } ## end of readline

    return $words;
} ## end sub Vote

__END__
## { SCALAR(0xbb713c) }{ wordcount= 2 }
## { SCALAR(0xad05a4) }{ wordcount= 9 }
## { SCALAR(0x3f8fec) }{ wordcount= 27 }
[download]